From abbb81b65c8798f25bebe75e7c88627056801325 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Fri, 5 Apr 2019 14:25:43 +0300
Subject: net-misc/modemmanager: bump to 1.10.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 net-misc/modemmanager/Manifest                   |   1 +
 net-misc/modemmanager/modemmanager-1.10.0.ebuild | 129 +++++++++++++++++++++++
 2 files changed, 130 insertions(+)
 create mode 100644 net-misc/modemmanager/modemmanager-1.10.0.ebuild

diff --git a/net-misc/modemmanager/Manifest b/net-misc/modemmanager/Manifest
index 983484905f6d..d30a9df75e4e 100644
--- a/net-misc/modemmanager/Manifest
+++ b/net-misc/modemmanager/Manifest
@@ -1 +1,2 @@
+DIST ModemManager-1.10.0.tar.xz 2201468 BLAKE2B 4a572feba7d62269ed9d6066565e1b7d41db3bece5d450796ee18f43a9a91a886f76dfe0db4887c9ca13643f72f4460c93b3dd2ae7643eb4c37b01905a3ff3c4 SHA512 676b11892b284c2da587895e71903f80ec96978c66eafae5e2d90e5c0f1dae18e50efc68b704c7907f01f208d585f5a8140316cf83e093df3f782c80949c33bc
 DIST ModemManager-1.8.2.tar.xz 2088248 BLAKE2B e53ec3dacac2b1d57191de0eba130ea575a40047e5faa1c813543f1ca17164d71a18478ec6c0392adabea94d2455ee510ceceefc16798fec6f26ec834ebbf84c SHA512 fb00ce6f3dc9795468e81ba295ad82e9586add2d7118661ea5f287a99afca97dc3aea64488393792bb1198e7abf2605bbc5ded2517980d67f8819931effdeea5
diff --git a/net-misc/modemmanager/modemmanager-1.10.0.ebuild b/net-misc/modemmanager/modemmanager-1.10.0.ebuild
new file mode 100644
index 000000000000..f7ea0d8471dc
--- /dev/null
+++ b/net-misc/modemmanager/modemmanager-1.10.0.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 user readme.gentoo-r1 systemd udev vala
+
+DESCRIPTION="Modem and mobile broadband management libraries"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/ModemManager/"
+SRC_URI="https://www.freedesktop.org/software/ModemManager/ModemManager-${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0/1" # subslot = dbus interface version, i.e. N in org.freedesktop.ModemManager${N}
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="elogind +introspection mbim policykit +qmi systemd +udev vala"
+REQUIRED_USE="
+	?? ( elogind systemd )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	udev? ( >=virtual/libgudev-230:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	mbim? ( >=net-libs/libmbim-1.18.0 )
+	policykit? ( >=sys-auth/polkit-0.106[introspection] )
+	qmi? ( >=net-libs/libqmi-1.22.0:= )
+	elogind? ( sys-auth/elogind )
+	systemd? ( >=sys-apps/systemd-209 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+S="${WORKDIR}/ModemManager-${PV}"
+
+src_prepare() {
+	DOC_CONTENTS="
+		If your USB modem shows up only as a storage device when you plug it in,
+		then you should install sys-apps/usb_modeswitch, which will automatically
+		switch it over to USB modem mode whenever you plug it in.\n"
+
+	if use policykit; then
+		DOC_CONTENTS+="\nTo control your modem without needing to enter the root password,
+			add your user account to the 'plugdev' group."
+	fi
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		--disable-more-warnings
+		--disable-static
+		--with-dist-version=${PVR}
+		--with-udev-base-dir="$(get_udevdir)"
+		$(use_with udev)
+		$(use_enable introspection)
+		$(use_with mbim)
+		$(use_with policykit polkit)
+		$(use_with systemd systemd-suspend-resume)
+		$(use_with systemd systemd-journal)
+		$(use_with qmi)
+		$(use_enable vala)
+	)
+	if use elogind; then
+		myconf+=(
+			--with-systemd-suspend-resume
+			LIBSYSTEMD_LOGIN_CFLAGS=`pkg-config --cflags "libelogind" 2>/dev/null`
+			LIBSYSTEMD_LOGIN_LIBS=`pkg-config --libs "libelogind" 2>/dev/null`
+		)
+	fi
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Allow users in plugdev group full control over their modem
+	if use policykit; then
+		insinto /usr/share/polkit-1/rules.d/
+		doins "${FILESDIR}"/01-org.freedesktop.ModemManager1.rules
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	use policykit && enewgroup plugdev
+
+	# The polkit rules file moved to /usr/share
+	old_rules="${EROOT}etc/polkit-1/rules.d/01-org.freedesktop.ModemManager.rules"
+	if [[ -f "${old_rules}" ]]; then
+		case "$(md5sum ${old_rules})" in
+		  c5ff02532cb1da2c7545c3069e5d0992* | 5c50f0dc603c0a56e2851a5ce9389335* )
+			# Automatically delete the old rules.d file if the user did not change it
+			elog
+			elog "Removing old ${old_rules} ..."
+			rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
+			;;
+		  * )
+			elog "The ${old_rules}"
+			elog "file moved to /usr/share/polkit-1/rules.d/ in >=modemmanager-0.5.2.0-r2"
+			elog "If you edited ${old_rules}"
+			elog "without changing its behavior, you may want to remove it."
+			;;
+		esac
+	fi
+
+	if ! use udev; then
+		ewarn "You have built ModemManager without udev support. You may have to teach it"
+		ewarn "about your modem port manually."
+	fi
+
+	systemd_reenable ModemManager.service
+
+	readme.gentoo_print_elog
+}
-- 
cgit v1.2.3-65-gdbad