From d107e7dadcc808bedfb6d0ff9cb1f161ce5db0e2 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Mon, 1 Aug 2022 00:51:45 +0200
Subject: app-laptop/mbpfan: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 app-laptop/mbpfan/mbpfan-2.2.1-r1.ebuild | 47 ++++++++++++++++++++++++++++++++
 app-laptop/mbpfan/mbpfan-2.2.1.ebuild    | 46 -------------------------------
 2 files changed, 47 insertions(+), 46 deletions(-)
 create mode 100644 app-laptop/mbpfan/mbpfan-2.2.1-r1.ebuild
 delete mode 100644 app-laptop/mbpfan/mbpfan-2.2.1.ebuild

diff --git a/app-laptop/mbpfan/mbpfan-2.2.1-r1.ebuild b/app-laptop/mbpfan/mbpfan-2.2.1-r1.ebuild
new file mode 100644
index 000000000000..1bbd3102e15e
--- /dev/null
+++ b/app-laptop/mbpfan/mbpfan-2.2.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="A simple daemon to control fan speed on all Macbook/Macbook Pros"
+HOMEPAGE="https://github.com/dgraziotin/mbpfan"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dgraziotin/${PN}.git"
+else
+	SRC_URI="https://github.com/dgraziotin/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="test" # will fail if the hardware is unavailable, not useful
+
+CONFIG_CHECK="~SENSORS_APPLESMC ~SENSORS_CORETEMP"
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+
+	# Decompress the man page to enable PM auto compression
+	gzip -d "${ED}"/usr/share/man/man8/mbpfan.8.gz || die
+
+	# Remove the empty systemd unit directory
+	# It doesn't actually install the unit file
+	rmdir --ignore-fail-on-non-empty -p "${ED}"/lib/systemd/system || die
+	# Actually install the sytstemd unit file
+	systemd_dounit ${PN}.service
+	# Install openrc init file
+	newinitd ${PN}.init.gentoo ${PN}
+
+	# make install doesn't install the docs in the right place
+	rm -r "${ED}"/usr/share/doc/${PN} || die
+
+	einstalldocs
+}
diff --git a/app-laptop/mbpfan/mbpfan-2.2.1.ebuild b/app-laptop/mbpfan/mbpfan-2.2.1.ebuild
deleted file mode 100644
index e1a4cb35e935..000000000000
--- a/app-laptop/mbpfan/mbpfan-2.2.1.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit linux-info systemd toolchain-funcs
-
-DESCRIPTION="A simple daemon to control fan speed on all Macbook/Macbook Pros"
-HOMEPAGE="https://github.com/dgraziotin/mbpfan"
-LICENSE="GPL-3+"
-SLOT="0"
-RESTRICT="test" # will fail if the hardware is unavailable, not useful
-
-if [[ "${PV}" = 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/dgraziotin/${PN}.git"
-else
-	SRC_URI="https://github.com/dgraziotin/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64"
-fi
-
-CONFIG_CHECK="~SENSORS_APPLESMC ~SENSORS_CORETEMP"
-
-src_compile() {
-	emake CC="$(tc-getCC)"
-}
-
-src_install() {
-	emake DESTDIR="${ED}" install
-
-	# Decompress the man page to enable PM auto compression
-	gzip -d "${ED}"/usr/share/man/man8/mbpfan.8.gz || die
-
-	# Remove the empty systemd unit directory
-	# It doesn't actually install the unit file
-	rmdir --ignore-fail-on-non-empty -p "${ED%/}/lib/systemd/system" || die
-	# Actually install the sytstemd unit file
-	systemd_dounit ${PN}.service
-	# Install openrc init file
-	newinitd ${PN}.init.gentoo ${PN}
-
-	# make install doesn't install the docs in the right place
-	rm -rf "${ED%/}/usr/share/doc/${PN}" || die
-
-	einstalldocs
-}
-- 
cgit v1.2.3-65-gdbad