From dae6c1e538a6ff700f7e65782e5011d031e614a4 Mon Sep 17 00:00:00 2001
From: Mikle Kolyada <zlogene@gentoo.org>
Date: Sun, 17 Mar 2019 01:40:05 +0300
Subject: mate-base/mate-applets: Version bump (v1.22.0)

Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11
---
 mate-base/mate-applets/Manifest                   |  1 +
 mate-base/mate-applets/mate-applets-1.22.0.ebuild | 90 +++++++++++++++++++++++
 2 files changed, 91 insertions(+)
 create mode 100644 mate-base/mate-applets/mate-applets-1.22.0.ebuild

diff --git a/mate-base/mate-applets/Manifest b/mate-base/mate-applets/Manifest
index eda4f67daee6..141439074725 100644
--- a/mate-base/mate-applets/Manifest
+++ b/mate-base/mate-applets/Manifest
@@ -1 +1,2 @@
 DIST mate-applets-1.18.2.tar.xz 7163260 BLAKE2B 58d057d1eded3ef26f33e133f86459a75df2903906f27df555640aaf51ca381e8f57b0b4fe6ed7b2d679e08d2a595fc85a6b0d9c4ad51d3ac01552e2875e00bb SHA512 6644a7dfde1dbf65c38cd3a0f52f862e096030f0b9f324f1fbfc34b6167c04b51071f01c322c3c8382e74843332c877b1340fe2129417d6cf9207c32ef2f70be
+DIST mate-applets-1.22.0.tar.xz 7739668 BLAKE2B dc3768d2f5eb987907f1ffb1a049dff990140c66c51427dc9095298be92b17b2b1e9695f3c35dae73433e1e50d05477e94aad1697b2bf15706515c16150096d7 SHA512 2f3e17414171ec5ab6967b76b1291d99783c3091b51127788f99148f46d5f2068edf7d890c3ebca1a59c29cbda4a06be11c852e5e88d4dc58e9981d906c9e34c
diff --git a/mate-base/mate-applets/mate-applets-1.22.0.ebuild b/mate-base/mate-applets/mate-applets-1.22.0.ebuild
new file mode 100644
index 000000000000..08a224fa6210
--- /dev/null
+++ b/mate-base/mate-applets/mate-applets-1.22.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit mate python-single-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Applets for the MATE Desktop and Panel"
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+
+IUSE="X ipv6 policykit +upower"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/atk
+	>=dev-libs/dbus-glib-0.74
+	>=dev-libs/glib-2.50:2
+	>=dev-libs/libmateweather-1.17.0
+	>=dev-libs/libxml2-2.5:2
+	dev-python/pygobject:3
+	>=gnome-base/libgtop-2.12.0:2=
+	>=gnome-extra/gucharmap-3.0:2.90
+	>=mate-base/mate-panel-1.17.0
+	>=net-wireless/wireless-tools-28_pre9:0
+	>=sys-apps/dbus-1.1.2
+	sys-power/cpupower
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/gtksourceview:3.0
+	>=x11-libs/libnotify-0.7
+	x11-libs/libX11
+	>=x11-libs/libwnck-3.0:3
+	x11-libs/pango
+	virtual/libintl
+	policykit? ( >=sys-auth/polkit-0.97:0 )
+	upower? ( >=sys-power/upower-0.9.23 )
+	!!net-analyzer/mate-netspeed"
+
+RDEPEND="${COMMON_DEPEND}
+	>=mate-base/mate-settings-daemon-1.6"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.3
+	app-text/rarian
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools
+	>=dev-util/intltool-0.50.1
+	dev-libs/libxslt
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+PATCHES=( "${FILESDIR}/${PN}-1.16.0-cpupower-4.7.patch" )
+
+src_configure() {
+	mate_src_configure \
+		--libexecdir=/usr/libexec/mate-applets \
+		--with-cpufreq-lib=cpupower \
+		$(use_with X x) \
+		$(use_with upower) \
+		$(use_enable ipv6) \
+		$(use_enable policykit polkit)
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	emake check
+}
+
+src_install() {
+	mate_src_install
+
+	local APPLETS="accessx-status battstat charpick command cpufreq drivemount
+			geyes mateweather multiload netspeed stickynotes
+			timerapplet trashapplet"
+
+	for applet in ${APPLETS}; do
+		docinto ${applet}
+
+		for d in AUTHORS ChangeLog NEWS README README.themes TODO; do
+			[ -s ${applet}/${d} ] && dodoc ${applet}/${d}
+		done
+	done
+}
-- 
cgit v1.2.3-65-gdbad