From e7075302b3782c561b5bf58f0b7b552d4a834a97 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 27 Apr 2019 15:08:39 +0200
Subject: app-crypt/qca: 2.2.1 version bump

Package-Manager: Portage-2.3.65, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 app-crypt/qca/Manifest         |  1 +
 app-crypt/qca/qca-2.2.1.ebuild | 87 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)
 create mode 100644 app-crypt/qca/qca-2.2.1.ebuild

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index 03db5e0d5f65..300dfbb1442a 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -1,2 +1,3 @@
 DIST qca-2.1.3.tar.xz 686340 BLAKE2B 60ebf9add907632ed17426ee53c6c35a9aed279a4492012f1c174608cbe9579d366feb7ff7bff551d2e9e4ef2f271e8f340fcb4c9e1f67f209657d388567d44f SHA512 0aec277e0695da2e45298f0a9006213829fe4c449a79969e472947db54f45000ba6e22361b782465bdc03f269b7301d318c843f5a83db459a118e58a03f3116a
 DIST qca-2.2.0.tar.xz 691264 BLAKE2B 3b9196372c8a8f2e50a86a8a581a549d52a324cbfa919945683222d605747f7127af469a1de0310e24e823243ab4cd884a763b7baac94048e739f49d2a31dcbf SHA512 2a3f73bbd73ae8f74b2b4ec143bc010b7efaba267fc3349fc681623f29a288f69e5c457597f4964f88172a98e0a7eba6d2555675704d5d7026df794b8f772e69
+DIST qca-2.2.1.tar.xz 691676 BLAKE2B d5bcc0d6e791811e1efcdbf2e09916fe40ad682b0e59b2993c73a5bd79e09fc28facdec81259a982bee05223c8dfce78b9a6b729ca4e566c0901a13b91575379 SHA512 3a0e8aa7cf3ea9a7244facaf1d521ebca2753af37636e7bf5f21c57ae880ac9682ae7d6d9fa5ce41b73568ff9538214956b89cd41228c2cb828d9068c2031a9c
diff --git a/app-crypt/qca/qca-2.2.1.ebuild b/app-crypt/qca/qca-2.2.1.ebuild
new file mode 100644
index 000000000000..d42db14e774d
--- /dev/null
+++ b/app-crypt/qca/qca-2.2.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+
+IUSE="botan debug doc examples gcrypt gpg libressl logger nss pkcs11 sasl softstore +ssl test"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	botan? ( dev-libs/botan:= )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+		dev-libs/pkcs11-helper
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-qt/qtnetwork:5
+		dev-qt/qttest:5
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-disable-pgp-test.patch" )
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(qt5_get_mkspecsdir)/features"
+		-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(qt5_get_plugindir)"
+		$(qca_plugin_use botan)
+		$(qca_plugin_use gcrypt)
+		$(qca_plugin_use gpg gnupg)
+		$(qca_plugin_use logger)
+		$(qca_plugin_use nss)
+		$(qca_plugin_use pkcs11)
+		$(qca_plugin_use sasl cyrus-sasl)
+		$(qca_plugin_use softstore)
+		$(qca_plugin_use ssl ossl)
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}
-- 
cgit v1.2.3-65-gdbad