From ef70acff0b978494600d37a530de2ec10ecb9f92 Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Fri, 19 Feb 2021 21:47:26 +0100
Subject: net-misc/owncloud-client: 2.7.6.3261 bump

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---
 net-misc/owncloud-client/Manifest                  |  1 +
 .../owncloud-client-2.7.6.3261.ebuild              | 84 ++++++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 net-misc/owncloud-client/owncloud-client-2.7.6.3261.ebuild

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 105a380bedcc..f6abf34b3093 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST ownCloud-2.7.4.2934.tar.xz 14151708 BLAKE2B ad6f3d827a2fdcead6fdc2514696e8fbdb75b2d365c9a09602b95b24c669695e3693167f5da305e27e6fb2266f106b50c578def1d1518730926a10f640defbd9 SHA512 7e04d987751d0b8e29fbe8ba8ae58f38fabd7f5007f7508d001532e595b00f58cce487b1d180928154286ffd6b01db1e6ca0407f7d675e8b101ec4ae8414f2a6
 DIST ownCloud-2.7.5.3180.tar.xz 14154036 BLAKE2B ebee57568b917c1c7dec8f41f172caf53d0bfe4eae5e24ec5c9adbf656bf667769b0ed341a13a899ff6a04cd779d92b145736dce5a4e72055d306b2f08e0a902 SHA512 9e788341c45753eb2d2c62d252cf453259474689fd7d498147e0f4548a9038bd44bdca1539f9617d383853f8f9ca2f24c575667fb96e2a1a4ceec30195d257c2
+DIST ownCloud-2.7.6.3261.tar.xz 14237692 BLAKE2B 914b069b10fa2f169677768e1578c5b8569836eb574889c72c0ea1ca3e16e6b7c65bcdd1f4a5ce4259eab6ec56110e3b45799d010921e47c7f64ccfd0ed545bf SHA512 1f647dd0b33472e31719651fa22b5864867d98fa1e2f11f9eadb6ce15382f5f97ac49d726af079716b6fac573367485a6f11a5b2e5e5c95d4d063f6caab51dcd
diff --git a/net-misc/owncloud-client/owncloud-client-2.7.6.3261.ebuild b/net-misc/owncloud-client/owncloud-client-2.7.6.3261.ebuild
new file mode 100644
index 000000000000..4afe35f947d5
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.7.6.3261.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin gnome-keyring nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	xdg_pkg_postinst
+}
-- 
cgit v1.2.3-65-gdbad