From e41771703356e344dd98066f85834e345bcd675f Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Wed, 31 May 2017 11:32:31 +0200
Subject: app-benchmarks/i7z: Apply Debian patches fixing multiple bugs, drop
 deprecated qt4 support
 (https://wiki.gentoo.org/wiki/Project:Qt/Policies#Handling_different_versions_of_Qt),
 allow -Ox for now as it looks to work ok for me with this version.

Package-Manager: Portage-2.3.6, Repoman-2.3.2
---
 app-benchmarks/i7z/i7z-93_p20131012-r1.ebuild | 69 +++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 app-benchmarks/i7z/i7z-93_p20131012-r1.ebuild

(limited to 'app-benchmarks/i7z/i7z-93_p20131012-r1.ebuild')

diff --git a/app-benchmarks/i7z/i7z-93_p20131012-r1.ebuild b/app-benchmarks/i7z/i7z-93_p20131012-r1.ebuild
new file mode 100644
index 000000000000..4e7ab8619aa2
--- /dev/null
+++ b/app-benchmarks/i7z/i7z-93_p20131012-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic qmake-utils toolchain-funcs
+
+COMMIT="5023138d7c35c4667c938b853e5ea89737334e92"
+DESCRIPTION="A better i7 (and now i3, i5) reporting tool for Linux"
+HOMEPAGE="https://github.com/ajaiantilal/i7z"
+SRC_URI="https://github.com/ajaiantilal/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="qt5"
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	qt5? (
+		dev-qt/qtcore:5=
+		dev-qt/qtgui:5=
+		dev-qt/qtwidgets:5=
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/i7z-0.27.2-ncurses.patch
+	"${FILESDIR}"/qt5.patch
+	"${FILESDIR}"/gcc5.patch
+
+	# From Debian
+	"${FILESDIR}"/fix-insecure-tempfile.patch
+	"${FILESDIR}"/fix_cpuid_asm.patch
+	"${FILESDIR}"/hyphen-used-as-minus-sign.patch
+	"${FILESDIR}"/install-i7z_rw_registers.patch
+	"${FILESDIR}"/use_stdbool.patch
+)
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_configure() {
+	# The GUI segfaults with -O1. None of the documented flags make a
+	# difference. There may not be a specific flag for the culprit.
+	# Looks to work fine for me with -O2 (pacho - 20170530)
+#	filter-flags "-O*"
+
+	tc-export CC
+	cd GUI || die
+
+	use qt5 && eqmake5 ${PN}_GUI.pro
+}
+
+src_compile() {
+	default
+
+	if use qt5; then
+		emake -C GUI clean
+		emake -C GUI
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${ED}" docdir=/usr/share/doc/${PF} install
+
+	if use qt5; then
+		dosbin GUI/i7z_GUI
+	fi
+}
-- 
cgit v1.2.3-65-gdbad