From 7eb295b857ea26267d017c9fac7b2e09de524d08 Mon Sep 17 00:00:00 2001
From: Manuel Rüger <mrueg@gentoo.org>
Date: Thu, 7 Dec 2017 19:17:31 +0100
Subject: app-emulation/docker-compose: Version bump to 1.18.0_rc1

Package-Manager: Portage-2.3.16, Repoman-2.3.6
---
 app-emulation/docker-compose/Manifest              |  1 +
 .../docker-compose-1.18.0_rc1.ebuild               | 71 ++++++++++++++++++++++
 2 files changed, 72 insertions(+)
 create mode 100644 app-emulation/docker-compose/docker-compose-1.18.0_rc1.ebuild

(limited to 'app-emulation/docker-compose')

diff --git a/app-emulation/docker-compose/Manifest b/app-emulation/docker-compose/Manifest
index e5fd849b8ac6..fb0d9caa5f69 100644
--- a/app-emulation/docker-compose/Manifest
+++ b/app-emulation/docker-compose/Manifest
@@ -1 +1,2 @@
 DIST docker-compose-1.17.1.tar.gz 219947 BLAKE2B a5438e66f156b98ffc9ecf63a57443610f76713532369d519689b697dbc91bd196e24b831882a4c39a43c5b17640242d98f47a2c337832395dc48019d58e3e90 SHA512 711c0a73546f0b396a920d3310b92fc15e3c13f93439eeda363124c9bd971aa942395b2405ad7441df8982384be367c20a767fe5b9e3e150690b63deda58f553
+DIST docker-compose-1.18.0_rc1.tar.gz 230199 BLAKE2B ccec8431c75be2beaf988e1f10a7e4587f9708f4a4b55280e335783250665b7ff660f1a781aa42b59ee7529fc26abf00e438904c9f9ca4ac0210f1f55490c36a SHA512 9d3e437f9a0889dc09c1c5ad141c0ebcee05d8ac9ec0e842d1544b58ec651270f397e4d41f08d2eab98c4e43cd0cfa950f287d6bcf8095f7972ab46e5a9c1c33
diff --git a/app-emulation/docker-compose/docker-compose-1.18.0_rc1.ebuild b/app-emulation/docker-compose/docker-compose-1.18.0_rc1.ebuild
new file mode 100644
index 000000000000..534ceb504f63
--- /dev/null
+++ b/app-emulation/docker-compose/docker-compose-1.18.0_rc1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 distutils-r1 vcs-snapshot
+
+MY_PV=${PV/_/}
+
+DESCRIPTION="Multi-container orchestration for Docker"
+HOMEPAGE="https://www.docker.com/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${PN}-${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+CDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cached-property-1.2.0[${PYTHON_USEDEP}]
+	<dev-python/cached-property-2[${PYTHON_USEDEP}]
+	>=dev-python/dockerpty-0.4.1[${PYTHON_USEDEP}]
+	<dev-python/dockerpty-0.5[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.6.1[${PYTHON_USEDEP}]
+	<dev-python/docker-py-3.0[${PYTHON_USEDEP}]
+	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
+	<dev-python/docopt-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.5.1[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-3[${PYTHON_USEDEP}]
+	>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+	!~dev-python/PySocks-1.5.7[${PYTHON_USEDEP}]
+	<dev-python/PySocks-2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	<dev-python/pyyaml-4[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.11.0[${PYTHON_USEDEP}]
+	<dev-python/requests-2.19[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.3.0[${PYTHON_USEDEP}]
+	<dev-python/six-2[${PYTHON_USEDEP}]
+	>=dev-python/texttable-0.9[${PYTHON_USEDEP}]
+	<dev-python/texttable-0.10[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+	<dev-python/websocket-client-1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/enum34-1.0.4[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '<dev-python/enum34-2[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '>=dev-python/ipaddress-1.0.16[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '>=dev-python/backports-ssl-match-hostname-3.5[${PYTHON_USEDEP}]' 'python2_7' )
+"
+DEPEND="
+	${CDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]' 'python2_7' )
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_test() {
+	${PYTHON} -m pytest tests/unit || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp contrib/completion/bash/docker-compose ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	doins contrib/completion/zsh/*
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad