From 46f7419a65fdface0529a914199b2918c54a48ed Mon Sep 17 00:00:00 2001
From: Matthias Maier <tamiko@gentoo.org>
Date: Sun, 28 Jul 2019 13:47:06 -0500
Subject: app-emulation/spice-vdagent: version bump to 0.19.0

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Matthias Maier <tamiko@gentoo.org>
---
 app-emulation/spice-vdagent/Manifest               |  1 +
 .../spice-vdagent/spice-vdagent-0.19.0.ebuild      | 70 ++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 app-emulation/spice-vdagent/spice-vdagent-0.19.0.ebuild

(limited to 'app-emulation/spice-vdagent')

diff --git a/app-emulation/spice-vdagent/Manifest b/app-emulation/spice-vdagent/Manifest
index 136c9215aacf..fd06cd9a0baf 100644
--- a/app-emulation/spice-vdagent/Manifest
+++ b/app-emulation/spice-vdagent/Manifest
@@ -1,2 +1,3 @@
 DIST spice-vdagent-0.17.0-patches-20180319.tar.xz 38924 BLAKE2B c7c7f851d307cd7dde620278c6ea240d71f8b1f25d6367f81213c7e902d2b2c15f72c71344f965743a45b5693832a2937041ca7b5511ce1db479dafe137bc7b1 SHA512 8ac627f56605151aebc100a6c6d61243776662150095c768196d750929971f98f4b6d1a831cfb547d29ae8a6734795c93e51a9c4f27dcf53bd66aca6df437c51
 DIST spice-vdagent-0.17.0.tar.bz2 130413 BLAKE2B b2fb522f491512d94ac15fa8d253e8e682210ad40657eb9e5e40489eaab18c9f1d5ef5f97075a4389501050a758e1f56d47132de6b1c74bb153fc6b5e87a698d SHA512 b26e44f6463ba70d5815956b301cc2351db22de41ed2ce8b2828d9bfa1cc581c86acd433f8f0d35d552d20f6ca140f88fa39b079ba26e9166dc07ad35bee502e
+DIST spice-vdagent-0.19.0.tar.bz2 151356 BLAKE2B b7a99a7205d955b27edfe483746e3f267a6e0b7885c4b8146ba42d99b581cf4e1748b503a37a3d6b66623ef2515b42756f2e6a5a4775d56def7aa396bd0dfb4f SHA512 f5056dfe66df3ee8205549be22bbc8c17d2196c8448eda97f01659ff30c34d9929f330767d7fafec557dc5f7fb9b65eaf85973193b38df774042de9b72d6e60d
diff --git a/app-emulation/spice-vdagent/spice-vdagent-0.19.0.ebuild b/app-emulation/spice-vdagent/spice-vdagent-0.19.0.ebuild
new file mode 100644
index 000000000000..aad36b37b093
--- /dev/null
+++ b/app-emulation/spice-vdagent/spice-vdagent-0.19.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info
+
+MY_P="${P/_*/}"
+PATCHSET="${P/*_p/}"
+
+DESCRIPTION="SPICE VD Linux Guest Agent"
+HOMEPAGE="https://www.spice-space.org/"
+SRC_URI="https://www.spice-space.org/download/releases/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+consolekit selinux systemd"
+S="${WORKDIR}/${MY_P}"
+
+CDEPEND="
+	>=app-emulation/spice-protocol-0.12.8
+	media-libs/alsa-lib
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libX11
+	x11-libs/libXinerama
+	consolekit? ( sys-auth/consolekit sys-apps/dbus )
+	systemd? ( sys-apps/systemd )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-vdagent )"
+
+CONFIG_CHECK="~INPUT_UINPUT ~VIRTIO_CONSOLE"
+ERROR_INPUT_UINPUT="User level input support (INPUT_UINPUT) is required"
+ERROR_VIRTIO_CONSOLE="VirtIO console/serial device support (VIRTIO_CONSOLE) is required"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local opt=()
+	if use consolekit; then
+		opt+=( --with-session-info=console-kit )
+	elif use systemd; then
+		opt+=( --with-session-info=systemd )
+	else
+		opt+=( --with-session-info=none )
+	fi
+
+	econf \
+		--with-init-script=systemd \
+		--localstatedir="${EPREFIX}"/var \
+		"${opt[@]}"
+}
+
+src_install() {
+	default
+
+	cd "${ED}" && rmdir -p var/run/spice-vdagentd || die
+
+	keepdir /var/log/spice-vdagentd
+
+	newinitd "${FILESDIR}/${PN}.initd-3" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd-2" "${PN}"
+}
-- 
cgit v1.2.3-65-gdbad