From d8a71ff746b3b2d48443df0452795166e5a42325 Mon Sep 17 00:00:00 2001
From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Sat, 19 Dec 2020 21:49:29 +0000
Subject: app-misc/pax-utils: bump up to 1.2.7

A few chages:
- drop strings based /lib extraction heuristics
- new --ldcache variable to redirect path to ld.so.cache
  (mostly for tests)

Closes: https://bugs.gentoo.org/736601
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---
 app-misc/pax-utils/Manifest               |  1 +
 app-misc/pax-utils/pax-utils-1.2.7.ebuild | 78 +++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 app-misc/pax-utils/pax-utils-1.2.7.ebuild

(limited to 'app-misc/pax-utils')

diff --git a/app-misc/pax-utils/Manifest b/app-misc/pax-utils/Manifest
index 66599d029bcd..767f75939b7d 100644
--- a/app-misc/pax-utils/Manifest
+++ b/app-misc/pax-utils/Manifest
@@ -1 +1,2 @@
 DIST pax-utils-1.2.6.tar.xz 680696 BLAKE2B b271e19ed5ec1024d7c6e5723c12464c6ab07646dfbfd4738bfe0250629205051642421425d7c7c5f540b1ac3d100c13d1beca398d9766f7f477830ab128eef2 SHA512 59fe16c5573414aa2952a99c5b85c16cf10dbbee76943f263d31d5b1aa8818a9b00fa78c8b6dadbe02216de54fc32b26d80303a17e2d854de6bb9dd8b431f617
+DIST pax-utils-1.2.7.tar.xz 689680 BLAKE2B 9d7dd0aeaecc10edf1dc70acef1561e3984b9d4f30f2ff54b27cdd91fb88d194e6f1bb9b2b01064a25a1842855dfe4f448f7267d69bbed0102a854635b5829aa SHA512 e3bbe7fe0cf7c1607218187f272edad3652a55317a620905b76bba5bc9617f31b8eced6760f353b4558e7b118664c3df5c6d97c78b653f8d4636f094b96307f8
diff --git a/app-misc/pax-utils/pax-utils-1.2.7.ebuild b/app-misc/pax-utils/pax-utils-1.2.7.ebuild
new file mode 100644
index 000000000000..97ad76dbc3c2
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.2.7.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit eutils python-single-r1 toolchain-funcs
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="caps debug kernel_linux python seccomp"
+
+RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pyelftools[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	seccomp? ( sys-libs/libseccomp )
+"
+# >=linux-headers-4.11 to pick linux headers with statx, bug #737094
+DEPEND="
+	${RDEPEND}
+	kernel_linux? ( !prefix-guest? ( >=sys-kernel/linux-headers-4.11 ) )
+"
+BDEPEND="
+	caps? ( virtual/pkgconfig )
+	seccomp? ( virtual/pkgconfig )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+_emake() {
+	emake \
+		USE_CAP=$(usex caps) \
+		USE_DEBUG=$(usex debug) \
+		USE_PYTHON=$(usex python) \
+		USE_SECCOMP=$(usex seccomp) \
+		"$@"
+}
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	# Avoid slow configure+gnulib+make if on an up-to-date Linux system
+	if use prefix || ! use kernel_linux ||
+		has_version '<sys-libs/glibc-2.10'
+	then
+		econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
+	else
+		tc-export CC PKG_CONFIG
+	fi
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake check
+}
+
+src_install() {
+	_emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+
+	use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}
-- 
cgit v1.2.3-65-gdbad