From f1755640c7f30db4bc392ee72585f12a39f15da6 Mon Sep 17 00:00:00 2001
From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Sun, 16 Feb 2020 13:04:31 +0000
Subject: app-misc/pax-utils: bump up to 1.2.5, bug #709794

Two minor changes:
- security.c: allow 'semtimedop' in seccomp sandbox (glibc-2.31)
- dumpelf.c: add missing break when decoding SHT_GNU_LIBLIST

Reported-by: Patrick McLean
Closes: https://bugs.gentoo.org/709794
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---
 app-misc/pax-utils/Manifest               |  1 +
 app-misc/pax-utils/pax-utils-1.2.5.ebuild | 72 +++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)
 create mode 100644 app-misc/pax-utils/pax-utils-1.2.5.ebuild

(limited to 'app-misc/pax-utils')

diff --git a/app-misc/pax-utils/Manifest b/app-misc/pax-utils/Manifest
index d256c08a6fd5..571ddff0d396 100644
--- a/app-misc/pax-utils/Manifest
+++ b/app-misc/pax-utils/Manifest
@@ -1 +1,2 @@
 DIST pax-utils-1.2.4.tar.xz 665648 BLAKE2B f0003f912e42a25c8b587764591f7c466aa4c7a24f38fe101d7b64ea5abca5511b2f9329fa5620d1b4ae1926c2272eb97d4ada0210d4e55d16c7766a055672f4 SHA512 03b84054c59e8ce64d2c07276c61245c8e9b3eca2fc430269531e2dafe120009b541ebb6adc4ff54c13a1da63caf0755fb026ba272cf17d04f75e06b893a3e95
+DIST pax-utils-1.2.5.tar.xz 679604 BLAKE2B 348c6ab52a5e950f346115802d596fd33142fe2d93a83d686fbec917d3f74c53c332f2fcbd197c5bdd38b545f48568c7b461143fa328433ce3ee931901012601 SHA512 bf2f47393a66b4218eba7981100fc6936c7c9d6d98970f5337e7b3097ce6f7b2ca13de486ff7450e4395b74ba2308d37105508234f323230376ec5814cfe54f9
diff --git a/app-misc/pax-utils/pax-utils-1.2.5.ebuild b/app-misc/pax-utils/pax-utils-1.2.5.ebuild
new file mode 100644
index 000000000000..1918cdf76e44
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.2.5.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit eutils python-single-r1 toolchain-funcs unpacker
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="caps debug python seccomp"
+
+RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pyelftools[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	seccomp? ( sys-libs/libseccomp )"
+DEPEND="${RDEPEND}
+	caps? ( virtual/pkgconfig )
+	seccomp? ( virtual/pkgconfig )
+	app-arch/xz-utils"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+_emake() {
+	emake \
+		USE_CAP=$(usex caps) \
+		USE_DEBUG=$(usex debug) \
+		USE_PYTHON=$(usex python) \
+		USE_SECCOMP=$(usex seccomp) \
+		"$@"
+}
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	# Avoid slow configure+gnulib+make if on an up-to-date Linux system
+	if use prefix || ! use kernel_linux ||
+		has_version '<sys-libs/glibc-2.10'
+	then
+		econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
+	else
+		tc-export CC PKG_CONFIG
+	fi
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake check
+}
+
+src_install() {
+	_emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+
+	use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}
-- 
cgit v1.2.3-65-gdbad