From 9691712ab99043188b7ba015ab928adee3e7cccf Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Thu, 25 Jun 2020 10:36:41 +0200
Subject: app-misc/oneko: Set BDEPEND

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Closes: https://bugs.gentoo.org/729540
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 app-misc/oneko/oneko-1.2_p6_p14-r1.ebuild | 68 +++++++++++++++++++++++++++++++
 app-misc/oneko/oneko-1.2_p6_p14.ebuild    | 66 ------------------------------
 2 files changed, 68 insertions(+), 66 deletions(-)
 create mode 100644 app-misc/oneko/oneko-1.2_p6_p14-r1.ebuild
 delete mode 100644 app-misc/oneko/oneko-1.2_p6_p14.ebuild

(limited to 'app-misc')

diff --git a/app-misc/oneko/oneko-1.2_p6_p14-r1.ebuild b/app-misc/oneko/oneko-1.2_p6_p14-r1.ebuild
new file mode 100644
index 000000000000..8ad80ac4a084
--- /dev/null
+++ b/app-misc/oneko/oneko-1.2_p6_p14-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop toolchain-funcs
+
+DESCRIPTION="A cat, dog and others which chase the mouse or windows around the screen"
+HOMEPAGE="http://www.daidouji.com/oneko/"
+SRC_URI="
+	mirror://debian/pool/main/o/${PN}/${PN}_$(ver_cut 1-2).sakura.$(ver_cut 4)-$(ver_cut 6).debian.tar.xz
+	mirror://debian/pool/main/o/${PN}/${PN}_$(ver_cut 1-2).sakura.$(ver_cut 4).orig.tar.gz
+	mirror://gentoo/${P/_p*}-cat.png
+	mirror://gentoo/${P/_p*}-dog.png
+"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	app-text/rman
+	x11-misc/gccmakedep
+	x11-misc/imake
+"
+PATCHES=(
+	"${FILESDIR}"/${P/_p*}-include.patch
+)
+S=${WORKDIR}/${PN}-$(ver_cut 1-2).sakura.$(ver_cut 4).orig
+
+src_prepare() {
+	for patch in $(< "${WORKDIR}"/debian/patches/series); do
+		eapply "${WORKDIR}"/debian/patches/${patch}
+	done
+
+	default
+}
+
+src_configure() {
+	xmkmf -a || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CCOPTIONS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin oneko
+	newman oneko._man oneko.1x
+	dodoc README README-NEW README-SUPP
+
+	newicon "${DISTDIR}"/${P/_*}-cat.png cat.png
+	newicon "${DISTDIR}"/${P/_*}-dog.png dog.png
+
+	make_desktop_entry "oneko" "oneko (cat)" "cat" "Game;Amusement"
+	make_desktop_entry "oneko -dog" "oneko (dog)" "dog" "Game;Amusement"
+	make_desktop_entry "killall -TERM oneko" "oneko kill" "" "Game;Amusement"
+}
diff --git a/app-misc/oneko/oneko-1.2_p6_p14.ebuild b/app-misc/oneko/oneko-1.2_p6_p14.ebuild
deleted file mode 100644
index 24af54e6b8a2..000000000000
--- a/app-misc/oneko/oneko-1.2_p6_p14.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-inherit desktop toolchain-funcs
-
-DESCRIPTION="A cat, dog and others which chase the mouse or windows around the screen"
-HOMEPAGE="http://www.daidouji.com/oneko/"
-SRC_URI="
-	mirror://debian/pool/main/o/${PN}/${PN}_$(ver_cut 1-2).sakura.$(ver_cut 4)-$(ver_cut 6).debian.tar.xz
-	mirror://debian/pool/main/o/${PN}/${PN}_$(ver_cut 1-2).sakura.$(ver_cut 4).orig.tar.gz
-	mirror://gentoo/${P/_p*}-cat.png
-	mirror://gentoo/${P/_p*}-dog.png
-"
-
-LICENSE="public-domain"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-
-RDEPEND="
-	x11-libs/libX11
-	x11-libs/libXext
-"
-DEPEND="
-	${RDEPEND}
-	app-text/rman
-	x11-base/xorg-proto
-	x11-misc/gccmakedep
-	x11-misc/imake
-"
-PATCHES=(
-	"${FILESDIR}"/${P/_p*}-include.patch
-)
-S=${WORKDIR}/${PN}-$(ver_cut 1-2).sakura.$(ver_cut 4).orig
-
-src_prepare() {
-	for patch in $(< "${WORKDIR}"/debian/patches/series); do
-		eapply "${WORKDIR}"/debian/patches/${patch}
-	done
-
-	default
-}
-
-src_configure() {
-	xmkmf -a || die
-}
-
-src_compile() {
-	emake \
-		CC="$(tc-getCC)" \
-		CCOPTIONS="${CFLAGS}" \
-		EXTRA_LDOPTIONS="${LDFLAGS}"
-}
-
-src_install() {
-	dobin oneko
-	newman oneko._man oneko.1x
-	dodoc README README-NEW README-SUPP
-
-	newicon "${DISTDIR}"/${P/_*}-cat.png cat.png
-	newicon "${DISTDIR}"/${P/_*}-dog.png dog.png
-
-	make_desktop_entry "oneko" "oneko (cat)" "cat" "Game;Amusement"
-	make_desktop_entry "oneko -dog" "oneko (dog)" "dog" "Game;Amusement"
-	make_desktop_entry "killall -TERM oneko" "oneko kill" "" "Game;Amusement"
-}
-- 
cgit v1.2.3-65-gdbad