From e82bc6711f0ee0c13bc7284510833bcc1db00835 Mon Sep 17 00:00:00 2001
From: Sebastian Pipping <sping@gentoo.org>
Date: Thu, 5 Mar 2020 15:40:42 +0100
Subject: app-portage/elogv: Fix setuptools dependency

Closes: https://bugs.gentoo.org/709906
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.92, Repoman-2.3.20
---
 app-portage/elogv/elogv-0.7.8-r3.ebuild | 57 +++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 app-portage/elogv/elogv-0.7.8-r3.ebuild

(limited to 'app-portage')

diff --git a/app-portage/elogv/elogv-0.7.8-r3.ebuild b/app-portage/elogv/elogv-0.7.8-r3.ebuild
new file mode 100644
index 000000000000..9bb9e95bbc71
--- /dev/null
+++ b/app-portage/elogv/elogv-0.7.8-r3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="ncurses"
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1
+
+DESCRIPTION="Curses based utility to parse the contents of elogs created by Portage"
+HOMEPAGE="https://github.com/gentoo/elogv"
+SRC_URI="https://github.com/gentoo/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+
+RDEPEND="sys-apps/portage[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+DOCS=( README )
+
+src_install() {
+	distutils-r1_src_install
+
+	# unset LINGUAS => install all languages
+	# empty LINGUAS => install none
+	local i
+	if [[ -n "${LINGUAS+x}" ]] ; then
+		for i in $(ls "${ED}"/usr/share/locale/) ; do
+			if ! has ${i} ${LINGUAS} ; then
+				rm -rf "${ED}"/usr/share/{locale,man}/${i}
+			fi
+		done
+	fi
+}
+
+pkg_postinst() {
+	elog "Optional dependencies:"
+	elog "  dev-python/pyliblzma (for xz compressed elog files)"
+	elog
+	elog "In order to use this software, you need to activate"
+	elog "Portage's elog features.  Required is"
+	elog "		 PORTAGE_ELOG_SYSTEM=\"save\" "
+	elog "and at least one out of "
+	elog "		 PORTAGE_ELOG_CLASSES=\"warn error info log qa\""
+	elog "More information on the elog system can be found"
+	elog "in ${EPREFIX}/usr/share/portage/config/make.conf.example"
+	elog
+	elog "To operate properly this software needs the directory"
+	elog "${PORT_LOGDIR:-${EPREFIX}/var/log/portage}/elog created, belonging to group portage."
+	elog "To start the software as a user, add yourself to the portage"
+	elog "group."
+	elog
+}
-- 
cgit v1.2.3-65-gdbad