From 569224ba9ca3095471752175b1ae2999ff17a88f Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Fri, 29 Nov 2019 10:46:12 +0100
Subject: app-text/poppler: Bump to version 0.83.0

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 app-text/poppler/Manifest              |   1 +
 app-text/poppler/poppler-0.83.0.ebuild | 122 +++++++++++++++++++++++++++++++++
 2 files changed, 123 insertions(+)
 create mode 100644 app-text/poppler/poppler-0.83.0.ebuild

(limited to 'app-text')

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 399498bfc9cc..e5c6dbe0e6c9 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -2,3 +2,4 @@ DIST poppler-0.79.0.tar.xz 1544140 BLAKE2B b5ecf204c5246f640d9f5ca5ffce9648a1a2c
 DIST poppler-0.80.0.tar.xz 1548908 BLAKE2B 09a3b10b1ee6a9de900f7a6ca105e98ec266995c3f6a3d56fbefb7b57851462caa4a16a55081efd8b70d02107d8b7a13a74e316d448290bb3b02286c1778ad86 SHA512 0a0d68168ba4d560941de31cb9e32c6cd7b44025e93cd84ace863ffab5b9ff0356524626cb16fb99c29a897738f2ac5862480fc54d42f8aecd2e3457f11c642f
 DIST poppler-0.81.0.tar.xz 1548944 BLAKE2B 23b460d50b22d8b42690c28156398fa3cf299ac24ea883dc8c79044c44aebc126388cab2f31e69c76c50750ef86bd5203958efbb1c353c582c0337e6e0486a85 SHA512 774d650c63afe2a0d6669daad4b286c2412a0c02581d7ea2cc37d71936f77dff92dc22217367561b7e4285c9c27dcfdca4c76c187d9c3c482db2f3549919b25b
 DIST poppler-0.82.0.tar.xz 1553336 BLAKE2B a83d476ce1174cb7789f857a52a8a9ed29dfe8863d082ef662508ad9957667349aa62b038fa1a52e9e7ae3ddf4701eb5fbd58545b041b6aebd69cb8b91376d8d SHA512 1631be30e398dd18a4e8c2cc893cf0d9469a98d93f02f2ffe3bc14857518b76674a10cafe89ee92b9886c3c6b03d50e214a6838c102f673a62789c9832cfa4a2
+DIST poppler-0.83.0.tar.xz 1555456 BLAKE2B 4ab24a85e879d0ddbf24cf7bab5b1da7c15fc026e88b4076dc2b8cd34d69a5bcc0113df20fabda6915afea880480613ba34be6e23b5b0d79a3c6197c92af7853 SHA512 bfde1e3cc4d9c626949aab770d84fccbe47bdde2331d3b9f5b98c24319eb573a5db62acbfa5a524b21ed0f195f8b163fee64677c2bd616d31d0bb219d1e66713
diff --git a/app-text/poppler/poppler-0.83.0.ebuild b/app-text/poppler/poppler-0.83.0.ebuild
new file mode 100644
index 000000000000..33ffc42f9cac
--- /dev/null
+++ b/app-text/poppler/poppler-0.83.0.ebuild
@@ -0,0 +1,122 @@
+# Copyright 2005-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/93"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="cairo cjk curl cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+DEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-libs/zlib
+	cairo? (
+		dev-libs/glib:2
+		x11-libs/cairo
+		introspection? ( dev-libs/gobject-introspection:= )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.19:0 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:0 )
+"
+RDEPEND="${DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.60.1-qt5-dependencies.patch"
+	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
+	"${FILESDIR}/${PN}-0.82.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.61.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if [[ ${CC} == clang ]] ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DENABLE_SPLASH=ON
+		-DENABLE_ZLIB=ON
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_CMS=$(usex lcms lcms2 none)
+		-DWITH_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		$(cmake-utils_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}
-- 
cgit v1.2.3-65-gdbad