From 88bdc10579f67180038744dac2aec0d78e9acb04 Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Fri, 19 Aug 2016 05:41:36 +1000
Subject: dev-games/tiled: version bump

Package-Manager: portage-2.3.0
---
 dev-games/tiled/Manifest            |  1 +
 dev-games/tiled/tiled-0.17.0.ebuild | 69 +++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 dev-games/tiled/tiled-0.17.0.ebuild

(limited to 'dev-games')

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index e619f8b88149..5c8c2cf85a07 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-0.16.2.tar.gz 4503339 SHA256 801f607ae1eb306cbffd5d3e42ac1131dca0c0be9511118e126c8cc842474351 SHA512 a8cd9aee4111586de16935e00824b4adcea69a8e610578fa1f0cf417d2320f5e60aa97796221c9962bfbb7a0198bcfc79c47cde6f43531165d93ab6c0263060f WHIRLPOOL b1960db6c7d70ff8be7a4fa0e03df3bfe779eecbc25562e4e6d5c61c7a4963d01f42b6f716f70d23b2cd14bf16a1a5a9fee42c806f49a08cecaf88dec61eeb83
+DIST tiled-0.17.0.tar.gz 4852620 SHA256 f7fce2006a04c9e6e5d45a15fb31d342a4a66f7a01e1e6bc0753035cfbf42f31 SHA512 bf9b0cdd08c9091238a5e37f0670f2f3c389a46892c682a81f817e5daae0e6e3b13edf5d61a4105d9064e44585a4d6c7f7956b4c69b14488ee04af1834bf066c WHIRLPOOL 9e8b21098016cb20be66071e115f678bd10531a63b99c949e8a0e04ba6302834c414cc1ddf294f36b13bf1e43c22b9403a2aa13dc52ddbe84c24eb95d9b88ddb
diff --git a/dev-games/tiled/tiled-0.17.0.ebuild b/dev-games/tiled/tiled-0.17.0.ebuild
new file mode 100644
index 000000000000..7caaf4710ef5
--- /dev/null
+++ b/dev-games/tiled/tiled-0.17.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit fdo-mime gnome2-utils multilib python-single-r1 qmake-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="http://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.6:5
+	>=dev-qt/qtgui-5.6:5
+	>=dev-qt/qtnetwork-5.6:5
+	>=dev-qt/qtopengl-5.6:5
+	>=dev-qt/qtwidgets-5.6:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
-- 
cgit v1.2.3