From b1285363d5455d15dcd837700a6f45338b0b2b57 Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Wed, 6 Oct 2021 15:08:09 +0300
Subject: dev-python/grpcio: add 1.41.0, enable py3.10

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 dev-python/grpcio/Manifest             |  1 +
 dev-python/grpcio/grpcio-1.41.0.ebuild | 47 ++++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)
 create mode 100644 dev-python/grpcio/grpcio-1.41.0.ebuild

(limited to 'dev-python/grpcio')

diff --git a/dev-python/grpcio/Manifest b/dev-python/grpcio/Manifest
index 4da9bd27415e..a17d9904222c 100644
--- a/dev-python/grpcio/Manifest
+++ b/dev-python/grpcio/Manifest
@@ -1 +1,2 @@
 DIST grpcio-1.38.1.tar.gz 21392075 BLAKE2B 92f1ad9e119fe346bc1f8f10ffe7067fb736c975ecd276eb8ab37a3b25d0a818fff76cec164db5745ac157ba7b94b841c6e66bb332d9f3b2c08974cab415a973 SHA512 c4f831ee654eec78f01c099fa5a6d9dc7e9551b1db5e5c89e3b8bd4e5c3bae622aee32cac9212bb60bc1baec98e4a49f8e18c0043bc90d1144729dee337072f9
+DIST grpcio-1.41.0.tar.gz 21214188 BLAKE2B ac534e34cc5ccf810c1d2006d11d18dd067f0eff68724375f68710dcfe63f016adc467d2c1453e310ac531ec03f2dfd5b0dd8ccc14a6dab94b1c5815b6e3a0ee SHA512 714c1da865864df994540ccc48e73e709f63ceb8617119e67b463f647783d65222b8ef760e2ac1ebaab0fe43442382c2859d796c8a30d6e1eaf511b7dac515a7
diff --git a/dev-python/grpcio/grpcio-1.41.0.ebuild b/dev-python/grpcio/grpcio-1.41.0.ebuild
new file mode 100644
index 000000000000..cf5915184db5
--- /dev/null
+++ b/dev-python/grpcio/grpcio-1.41.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 multiprocessing prefix
+
+DESCRIPTION="High-performance RPC framework (python libraries)"
+HOMEPAGE="https://grpc.io"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/openssl-1.0.2:0=[-bindist(-)]
+	>=dev-libs/re2-0.2021.04.01:=
+	>=dev-python/cython-0.28.3[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	net-dns/c-ares:=
+	sys-libs/zlib:=
+"
+
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/1.37.1-cc-flag-test-fix.patch" )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	hprefixify setup.py
+}
+
+python_configure_all() {
+	# os.environ.get('GRPC_BUILD_WITH_BORING_SSL_ASM', True)
+	export GRPC_BUILD_WITH_BORING_SSL_ASM=
+	export GRPC_PYTHON_DISABLE_LIBC_COMPATIBILITY=1
+	export GRPC_PYTHON_BUILD_SYSTEM_CARES=1
+	export GRPC_PYTHON_BUILD_SYSTEM_OPENSSL=1
+	export GRPC_PYTHON_BUILD_WITH_SYSTEM_RE2=1
+	export GRPC_PYTHON_BUILD_SYSTEM_ZLIB=1
+	export GRPC_PYTHON_BUILD_WITH_CYTHON=1
+	export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$(makeopts_jobs)"
+}
-- 
cgit v1.2.3-65-gdbad