From 2f84a5f846fddd0689574fd86d0492dcd36bc02a Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 2 Feb 2020 16:13:27 +0100
Subject: dev-python/pyro: Bump to 4.78
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pyro/Manifest         |  1 +
 dev-python/pyro/pyro-4.78.ebuild | 65 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)
 create mode 100644 dev-python/pyro/pyro-4.78.ebuild

(limited to 'dev-python/pyro')

diff --git a/dev-python/pyro/Manifest b/dev-python/pyro/Manifest
index a8139fed667e..2f2d13df1166 100644
--- a/dev-python/pyro/Manifest
+++ b/dev-python/pyro/Manifest
@@ -1 +1,2 @@
 DIST Pyro4-4.77.tar.gz 479025 BLAKE2B 20c7b53cea55b77efea11cd7b74a1cfcc45ad721ba45e039947f1d869291bfcb054f16bc48fb5ad21386fe7d47785514ff94953b1bcf893266c2c41015bba589 SHA512 52a9f90cec8c5e23ec30ddb69484a15bb86d61024d1bc718d075e01678a3d9655a1ed21f18da1891c121bf0e95282fb1151762b2fdb826a6408056079d2b1a66
+DIST Pyro4-4.78.tar.gz 490988 BLAKE2B 0fbd7129557d2b1603176a34106f9e287faa6e1725eeede7a7427c0b975f2c4e136dc4ce1573e826c43211a903fee0d7baca85fb8ae58360da7869a3309a1a2d SHA512 7a95828f6c8d9d94b8a5263c63263335c3bfaa54c5e527bd8e61d2bc00d4cdb3c4c6a92155af189401b892a6729ad91dad207e389ff43ee342a011b95ddc90e5
diff --git a/dev-python/pyro/pyro-4.78.ebuild b/dev-python/pyro/pyro-4.78.ebuild
new file mode 100644
index 000000000000..493fa5c46b95
--- /dev/null
+++ b/dev-python/pyro/pyro-4.78.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="https://pypi.org/project/Pyro4/
+	https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~arm64 ~ppc ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!dev-python/pyro:0
+	$(python_gen_cond_dep \
+		'dev-python/selectors34[${PYTHON_USEDEP}]' -2)
+	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
+		dev-python/dill[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.4.6[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable tests requiring network connection.
+	rm tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad