From bc4e6cdfa0d748afb83c1bcd69bd4bdc89e983b3 Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Mon, 27 Sep 2021 14:31:05 +0300
Subject: dev-python/requests-cache: cleanup deps

 - Add optional dependencies
 - Add missing test deps
 - Add missing rdeps

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 .../requests-cache/requests-cache-0.8.1-r1.ebuild  | 67 ++++++++++++++++++++++
 .../requests-cache/requests-cache-0.8.1.ebuild     | 54 -----------------
 2 files changed, 67 insertions(+), 54 deletions(-)
 create mode 100644 dev-python/requests-cache/requests-cache-0.8.1-r1.ebuild
 delete mode 100644 dev-python/requests-cache/requests-cache-0.8.1.ebuild

(limited to 'dev-python/requests-cache')

diff --git a/dev-python/requests-cache/requests-cache-0.8.1-r1.ebuild b/dev-python/requests-cache/requests-cache-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..b5921df49217
--- /dev/null
+++ b/dev-python/requests-cache/requests-cache-0.8.1-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 optfeature
+
+HOMEPAGE="
+	https://pypi.org/project/requests-cache/
+	https://github.com/reclosedev/requests-cache/"
+DESCRIPTION="Persistent cache for requests library"
+SRC_URI="
+	https://github.com/reclosedev/requests-cache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	dev-python/cattrs[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	>=dev-python/url-normalize-1.4[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/itsdangerous[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# These require extra servers running
+		tests/integration/test_dynamodb.py
+		tests/integration/test_gridfs.py
+		tests/integration/test_mongodb.py
+		tests/integration/test_redis.py
+	)
+	local EPYTEST_DESELECT=(
+		# Requires Internet access
+		tests/integration/test_compat.py::test_version_upgrade
+	)
+
+	local -x USE_PYTEST_HTTPBIN=true
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "redis backend" "dev-python/redis-py"
+	optfeature "MongoDB backend" "dev-python/pymongo"
+
+	optfeature "JSON serialization" "dev-python/ujson"
+	optfeature "YAML serialization" "dev-python/pyyaml"
+	optfeature "signing serialized data" "dev-python/itsdangerous"
+}
diff --git a/dev-python/requests-cache/requests-cache-0.8.1.ebuild b/dev-python/requests-cache/requests-cache-0.8.1.ebuild
deleted file mode 100644
index 61afa9af0454..000000000000
--- a/dev-python/requests-cache/requests-cache-0.8.1.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_SETUPTOOLS=pyproject.toml
-PYTHON_COMPAT=( python3_{8..10} )
-PYTHON_REQ_USE="sqlite"
-
-inherit distutils-r1
-
-HOMEPAGE="
-	https://pypi.org/project/requests-cache/
-	https://github.com/reclosedev/requests-cache/"
-DESCRIPTION="Persistent cache for requests library"
-SRC_URI="
-	https://github.com/reclosedev/requests-cache/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/cattrs[${PYTHON_USEDEP}]
-	dev-python/itsdangerous[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
-	>=dev-python/url-normalize-1.4[${PYTHON_USEDEP}]"
-BDEPEND="
-	test? (
-		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
-		dev-python/requests-mock[${PYTHON_USEDEP}]
-		dev-python/responses[${PYTHON_USEDEP}]
-		dev-python/timeout-decorator[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# These require extra servers running
-		tests/integration/test_dynamodb.py
-		tests/integration/test_gridfs.py
-		tests/integration/test_mongodb.py
-		tests/integration/test_redis.py
-	)
-	local EPYTEST_DESELECT=(
-		# Requires Internet access
-		tests/integration/test_compat.py::test_version_upgrade
-	)
-
-	local -x USE_PYTEST_HTTPBIN=true
-	epytest
-}
-- 
cgit v1.2.3-65-gdbad