From 49072e0dcb81d28fcbf7f40b8389899815b0e9f6 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 20 May 2022 21:35:19 +0200
Subject: dev-qt/qtmultimedia: 5.15.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-qt/qtmultimedia/Manifest                   |  1 +
 dev-qt/qtmultimedia/qtmultimedia-5.15.4.ebuild | 71 ++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)
 create mode 100644 dev-qt/qtmultimedia/qtmultimedia-5.15.4.ebuild

(limited to 'dev-qt/qtmultimedia')

diff --git a/dev-qt/qtmultimedia/Manifest b/dev-qt/qtmultimedia/Manifest
index ee6b82f083fe..1c5315918e23 100644
--- a/dev-qt/qtmultimedia/Manifest
+++ b/dev-qt/qtmultimedia/Manifest
@@ -1 +1,2 @@
 DIST qtmultimedia-everywhere-opensource-src-5.15.3.tar.xz 3828384 BLAKE2B d6b9c892411d25381aa8fbb648f6989808f56cbeebb4df5cbbba87f18694b7d03de741ff65654bcb2ac5e0953c97db4a1d039887cf61e485a2651693a2553518 SHA512 8206df23a84ce77d234a97cd4847f7185d7b5ca2c6bf1cd48dc19c833a302f92f85c53d8bccd4bcfbfb6cdc82c2246b2fb62400eefd5d4b152e95e378dded668
+DIST qtmultimedia-everywhere-opensource-src-5.15.4.tar.xz 3833720 BLAKE2B bd381125280527eee7b5cec117c3d4c64ce2000b459effc1d912e5209d57bd88baf547967d61eefc94adf3f8aa85e3caf010b7ca9f7551b29182a90f483c5cfd SHA512 bb0ada7560093b89751b5b3c0e1a573de215a388d621d356bc3c0e1acfffc2d696230c67b7a7cef037b18c4da900c7eb3d315bd2e73ce12f9aedd0e340399117
diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.15.4.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.15.4.ebuild
new file mode 100644
index 000000000000..b09333980ab5
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.15.4.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt5-build
+
+DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="alsa gles2-only gstreamer openal pulseaudio qml widgets"
+
+RDEPEND="
+	=dev-qt/qtcore-${QT5_PV}*
+	=dev-qt/qtgui-${QT5_PV}*[gles2-only=]
+	=dev-qt/qtnetwork-${QT5_PV}*
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	pulseaudio? ( media-sound/pulseaudio[glib] )
+	qml? (
+		=dev-qt/qtdeclarative-${QT5_PV}*
+		gles2-only? ( =dev-qt/qtgui-${QT5_PV}*[egl] )
+		openal? ( media-libs/openal )
+	)
+	widgets? (
+		=dev-qt/qtwidgets-${QT5_PV}*[gles2-only=]
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.15.2-no-qtopengl.patch" )
+
+src_prepare() {
+	sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
+		src/multimedia/multimedia.pro || die
+
+	qt_use_disable_config openal openal \
+		src/imports/imports.pro
+
+	qt_use_disable_mod qml quick \
+		src/src.pro \
+		src/plugins/plugins.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/gsttools/gsttools.pro \
+		src/plugins/gstreamer/common.pri
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use alsa)
+		$(qt_use gstreamer)
+		$(qt_use pulseaudio)
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3-65-gdbad