From 1601fc818501e8e9ae4a410466bc60bb63819e6c Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Mon, 25 Mar 2019 21:09:31 +0100
Subject: dev-tex/rail: Fix LICENSE, fix QA issues.
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Update ebuild to EAPI 7.
Change LICENSE to public domain.
Fix dependencies.
Respect CC, CFLAGS, and LDFLAGS.
Build and install documentation properly.

Closes: https://bugs.gentoo.org/87542
Closes: https://bugs.gentoo.org/453148
Closes: https://bugs.gentoo.org/625904
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 dev-tex/rail/rail-1.2_p1-r1.ebuild | 35 +++++++++++++++++++++++++++++++++++
 dev-tex/rail/rail-1.2_p1.ebuild    | 36 ------------------------------------
 2 files changed, 35 insertions(+), 36 deletions(-)
 create mode 100644 dev-tex/rail/rail-1.2_p1-r1.ebuild
 delete mode 100644 dev-tex/rail/rail-1.2_p1.ebuild

(limited to 'dev-tex/rail')

diff --git a/dev-tex/rail/rail-1.2_p1-r1.ebuild b/dev-tex/rail/rail-1.2_p1-r1.ebuild
new file mode 100644
index 000000000000..eb33e29088b4
--- /dev/null
+++ b/dev-tex/rail/rail-1.2_p1-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit latex-package toolchain-funcs
+
+DESCRIPTION="Offers syntax/railroad diagrams"
+HOMEPAGE="http://www.ctan.org/tex-archive/support/rail/"
+SRC_URI="http://mirror.ctan.org/support/${PN}.zip -> ${P}.zip"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="app-arch/unzip
+	sys-devel/bison
+	sys-devel/flex"
+
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	emake -j1 \
+		CC="$(tc-getCC)" \
+		CFLAGS="-DYYDEBUG ${CFLAGS} ${LDFLAGS}" \
+		rail rail.dvi
+}
+
+src_install() {
+	local LATEX_PACKAGE_SKIP="try.tex"
+
+	latex-package_src_doinstall sty doc
+	dobin rail
+	newman rail.man rail.1
+}
diff --git a/dev-tex/rail/rail-1.2_p1.ebuild b/dev-tex/rail/rail-1.2_p1.ebuild
deleted file mode 100644
index a46c1e07fe0c..000000000000
--- a/dev-tex/rail/rail-1.2_p1.ebuild
+++ /dev/null
@@ -1,36 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="4"
-
-inherit latex-package
-
-DESCRIPTION="Offers syntax/railroad diagrams"
-HOMEPAGE="http://www.ctan.org/tex-archive/support/rail/"
-SRC_URI="http://mirror.ctan.org/support/${PN}.zip
-	-> ${P}.zip"
-
-LICENSE="LPPL-1.2"
-SLOT="0"
-KEYWORDS="~x86 ~amd64"
-IUSE=""
-
-RDEPEND="app-text/texlive"
-DEPEND="${RDEPEND}
-	app-arch/unzip
-	sys-devel/bison
-	sys-devel/flex"
-
-S=${WORKDIR}/${PN}
-
-src_compile() {
-	emake -j 1 || die "make failed"
-}
-
-src_install() {
-	latex-package_src_doinstall sty doc
-
-	dobin rail || die "Installing the rail tool failed"
-
-	newman rail.man rail.1 || die "Installing the manpage failed"
-}
-- 
cgit v1.2.3-65-gdbad