From 801b7c947105d8e3d24990e72a41f4622f722e9b Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Thu, 5 Nov 2015 13:20:48 +0100
Subject: dev-util/scanmem: Bump to version 0.15.3

Package-Manager: portage-2.2.24
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-util/scanmem/scanmem-0.15.3.ebuild | 53 ++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-util/scanmem/scanmem-0.15.3.ebuild

(limited to 'dev-util/scanmem/scanmem-0.15.3.ebuild')

diff --git a/dev-util/scanmem/scanmem-0.15.3.ebuild b/dev-util/scanmem/scanmem-0.15.3.ebuild
new file mode 100644
index 000000000000..1ddc4936ea04
--- /dev/null
+++ b/dev-util/scanmem/scanmem-0.15.3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit autotools eutils python-single-r1
+
+DESCRIPTION="Locate and modify variables in executing processes"
+HOMEPAGE="https://github.com/scanmem/scanmem"
+SRC_URI="https://github.com/scanmem/scanmem/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gui"
+
+DEPEND="sys-libs/readline:="
+RDEPEND="${DEPEND}
+	gui? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3
+		sys-auth/polkit
+	)"
+
+REQUIRED_USE="gui? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use gui && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -i "/CFLAGS/d" Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		$(use_enable gui)
+}
+
+src_install() {
+	default
+
+	if use gui ; then
+		docinto gui
+		dodoc gui/{README,TODO}
+		python_fix_shebang "${D}"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad