From a441511bc3a71801fcd64a7ed44b582e87fe4f5f Mon Sep 17 00:00:00 2001
From: Tupone Alfredo <tupone@gentoo.org>
Date: Thu, 3 May 2018 22:07:04 +0200
Subject: games-action/bzflag: Version bump to 2.4.14

Package-Manager: Portage-2.3.24, Repoman-2.3.6
---
 games-action/bzflag/bzflag-2.4.14.ebuild | 62 ++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 games-action/bzflag/bzflag-2.4.14.ebuild

(limited to 'games-action/bzflag/bzflag-2.4.14.ebuild')

diff --git a/games-action/bzflag/bzflag-2.4.14.ebuild b/games-action/bzflag/bzflag-2.4.14.ebuild
new file mode 100644
index 000000000000..cf647d42a263
--- /dev/null
+++ b/games-action/bzflag/bzflag-2.4.14.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils flag-o-matic autotools
+
+DESCRIPTION="3D tank combat simulator game"
+HOMEPAGE="https://www.bzflag.org/"
+SRC_URI="https://download.bzflag.org/bzflag/source/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated upnp"
+
+DEPEND="
+	net-dns/c-ares
+	>=net-misc/curl-7.15.0
+	sys-libs/ncurses:0
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2[joystick,sound,video]
+		virtual/glu
+		virtual/opengl )
+	upnp? ( net-libs/miniupnpc )"
+RDEPEND=${DEPEND}
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.12-configure.patch
+	"${FILESDIR}"/${PN}-2.4.12-tinfo.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if use dedicated ; then
+		ewarn
+		ewarn "You are building a server-only copy of BZFlag"
+		ewarn
+		myconf="--disable-client --without-SDL"
+	fi
+
+	econf \
+		$(use_enable upnp UPnP) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog DEVINFO PORTING README README.Linux" \
+		default
+
+	if ! use dedicated ; then
+		newicon data/bzflag-48x48.png ${PN}.png
+		make_desktop_entry ${PN} "BZFlag"
+	fi
+
+	prune_libtool_files --modules
+}
-- 
cgit v1.2.3-65-gdbad