From b90278cb754debe173cea88bff0d96e869b15068 Mon Sep 17 00:00:00 2001
From: Andrey Grozin <grozin@gentoo.org>
Date: Wed, 3 Apr 2019 14:34:05 +0200
Subject: games-board/pysolfc: bump to 2.6.2, compatibility with pillow-6

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andrey Grozin <grozin@gentoo.org>
---
 games-board/pysolfc/pysolfc-2.6.2.ebuild | 70 ++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 games-board/pysolfc/pysolfc-2.6.2.ebuild

(limited to 'games-board/pysolfc/pysolfc-2.6.2.ebuild')

diff --git a/games-board/pysolfc/pysolfc-2.6.2.ebuild b/games-board/pysolfc/pysolfc-2.6.2.ebuild
new file mode 100644
index 000000000000..04193353ffbf
--- /dev/null
+++ b/games-board/pysolfc/pysolfc-2.6.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6} )
+PYTHON_REQ_USE="tk"
+
+inherit eutils distutils-r1
+
+MY_PN=PySolFC
+
+DESCRIPTION="An exciting collection of more than 1000 solitaire card games"
+HOMEPAGE="http://pysolfc.sourceforge.net/"
+SRC_URI="https://github.com/shlomif/${MY_PN}/archive/${P}.tar.gz
+	extra-cardsets? ( mirror://sourceforge/${PN}/archive/${P}/${MY_PN}-Cardsets-2.0.tar.bz2 )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="extra-cardsets minimal +sound"
+
+S=${WORKDIR}/${MY_PN}-${P}
+
+DEPEND="dev-python/six"
+RDEPEND="${DEPEND}
+	python_targets_python3_5? ( dev-python/random2[python_targets_python3_5] )
+	python_targets_python3_6? ( dev-python/random2[python_targets_python3_6] )
+	!minimal? ( dev-python/pillow[tk,${PYTHON_USEDEP}]
+		dev-tcltk/tktable )
+	sound? ( dev-python/pygame[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-gentoo.patch" #591904
+	"${FILESDIR}/${PN}-locales.patch"
+	"${FILESDIR}/${PN}-pillow-6.patch"
+)
+
+python_prepare_all() {
+	sed -i \
+		-e "/pysol.desktop/d" \
+		-e "s:share/icons:share/pixmaps:" \
+		-e "s:data_dir =.*:data_dir = \'/usr/share/${PN}\':" \
+		setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	pushd html-src > /dev/null || die "html-src not found"
+	PYTHONPATH=.. "${EPYTHON}" gen-html.py || die "gen-html failed"
+	mv images html/ || die "mv images failed"
+	popd > /dev/null
+}
+
+python_install_all() {
+	make_desktop_entry pysol.py "PySol Fan Club Edition" pysol02
+
+	if use extra-cardsets; then
+		insinto /usr/share/${PN}
+		doins -r "${WORKDIR}"/${MY_PN}-Cardsets-2.0/*
+	fi
+
+	dosym /usr/share/doc/${PF}/html /usr/share/${PN}/html
+
+	doman docs/*.6
+	DOCS=( README.md AUTHORS docs/README docs/README.SOURCE )
+	HTML_DOCS=( html-src/html/. )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad