From 00ba9a6ea2754bba41483967f967c0afdae4c117 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Fri, 31 Aug 2018 23:04:41 +0300
Subject: games-board/gnome-chess: bump to 3.28.1

Package-Manager: Portage-2.3.48, Repoman-2.3.10
---
 games-board/gnome-chess/Manifest                  |  1 +
 games-board/gnome-chess/gnome-chess-3.28.1.ebuild | 54 +++++++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 games-board/gnome-chess/gnome-chess-3.28.1.ebuild

(limited to 'games-board')

diff --git a/games-board/gnome-chess/Manifest b/games-board/gnome-chess/Manifest
index a07ad351d010..f81a0570f94f 100644
--- a/games-board/gnome-chess/Manifest
+++ b/games-board/gnome-chess/Manifest
@@ -1 +1,2 @@
 DIST gnome-chess-3.24.1.tar.xz 2808208 BLAKE2B 6b6eefb8de8e7b91b23752d78d00704546566f060c8971c4fb17b26a28ca44b659891e036f5cc1f42bbfca41d1aaaca153758115eafb4456a3ddb45fe4caf1a8 SHA512 738bae74a547ccf9f0f3dcccaf164af785086ab54190094d602effae0f3f7c07fb6be4eba4aa8706045f70cb12c407a5151bc836d784c0cd254b1c371670e559
+DIST gnome-chess-3.28.1.tar.xz 1697524 BLAKE2B 743147e86fbaf5b1b1d84e802fde439de8a04f1e58607e34d0c5f660e59f3dd1e29aef1c763e5a00fa44581502c1d702a7fd9dfc826281f4dc703b23430a1efc SHA512 296703362fab5afa221130293d09a2f4e8d36d211f6fde7cee54c52a7ccec4c3a8aa5359baaf330e95cfd42277e2f95d44d762518a86d675c8e8a7237ebd9dd1
diff --git a/games-board/gnome-chess/gnome-chess-3.28.1.ebuild b/games-board/gnome-chess/gnome-chess-3.28.1.ebuild
new file mode 100644
index 000000000000..ddb05746bd32
--- /dev/null
+++ b/games-board/gnome-chess/gnome-chess-3.28.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_MIN_API_VERSION="0.36"
+
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Play the classic two-player boardgame of chess"
+HOMEPAGE="https://wiki.gnome.org/Apps/Chess"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.19:3
+	>=gnome-base/librsvg-2.32.0:2
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	app-text/yelp-tools
+	dev-libs/appstream-glib
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DOC_CONTENTS="For being able to play against computer you will
+need to install a chess engine like, for example, games-board/gnuchess"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-18-g5258