From 10bf6cb738b3a1ae0d3b1f39b4986c1fb9d6d09f Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Tue, 1 May 2018 14:29:26 +0200
Subject: games-puzzle/lpairs: Stop using games.eclass

Package-Manager: Portage-2.3.31, Repoman-2.3.9
---
 games-puzzle/lpairs/lpairs-1.0.4-r1.ebuild | 45 ++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 games-puzzle/lpairs/lpairs-1.0.4-r1.ebuild

(limited to 'games-puzzle/lpairs')

diff --git a/games-puzzle/lpairs/lpairs-1.0.4-r1.ebuild b/games-puzzle/lpairs/lpairs-1.0.4-r1.ebuild
new file mode 100644
index 000000000000..0f13cdb89b69
--- /dev/null
+++ b/games-puzzle/lpairs/lpairs-1.0.4-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit desktop
+
+DESCRIPTION="A classical memory game"
+HOMEPAGE="http://lgames.sourceforge.net/LPairs/"
+SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls sound"
+
+RDEPEND="
+	media-libs/libsdl[sound?,video]
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	default
+	sed -i \
+		-e 's:$localedir:/usr/share/locale:' \
+		-e 's:$(localedir):/usr/share/locale:' \
+		configure po/Makefile.in.in || die
+	# gcc5 doesn't like the way inline is used.  just punt it. (bug #568684)
+	sed -i -e 's/^inline//g' lpairs/{sdl.[ch],pairs.[ch]} || die
+}
+
+src_configure() {
+	econf \
+		--datadir=/usr \
+		$(use_enable nls) \
+		$(usex sound '' --disable-sound)
+}
+
+src_install() {
+	default
+	doicon lpairs.png
+	make_desktop_entry lpairs LPairs
+}
-- 
cgit v1.2.3-65-gdbad