From d2aae58c28dc04ad6fce65c60d3ef352abdb7af8 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 6 Apr 2021 01:59:56 +0100
Subject: games-puzzle/splice: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>
---
 games-puzzle/splice/splice-20121120-r1.ebuild | 59 ++++++++++++++++++++++++++
 games-puzzle/splice/splice-20121120.ebuild    | 60 ---------------------------
 2 files changed, 59 insertions(+), 60 deletions(-)
 create mode 100644 games-puzzle/splice/splice-20121120-r1.ebuild
 delete mode 100644 games-puzzle/splice/splice-20121120.ebuild

(limited to 'games-puzzle')

diff --git a/games-puzzle/splice/splice-20121120-r1.ebuild b/games-puzzle/splice/splice-20121120-r1.ebuild
new file mode 100644
index 000000000000..91d02c164129
--- /dev/null
+++ b/games-puzzle/splice/splice-20121120-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop wrapper
+
+DESCRIPTION="An experimental and artistic puzzler set in a microbial world"
+HOMEPAGE="http://www.cipherprime.com/games/splice/"
+SRC_URI="splice-linux-1353389454.tar.gz"
+S="${WORKDIR}"/Linux
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+
+RESTRICT="bindist fetch splitdebug"
+
+MYGAMEDIR=opt/${PN}
+QA_PREBUILT="
+	${MYGAMEDIR#/}/Splice*
+	${MYGAMEDIR#/}/Splice_Data/Mono/*
+"
+
+# TODO: unbundle mono? (seems hardcoded)
+#       icon
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXext"
+
+pkg_nofetch() {
+	einfo "Please buy & download ${SRC_URI} from:"
+	einfo "  ${HOMEPAGE}"
+	einfo "and move it to your DISTDIR directory."
+}
+
+src_prepare() {
+	einfo "Removing ${ARCH} unrelated files..."
+	rm -v Splice.x86$(usex amd64 "" "_64") || die
+	rm -rv Splice_Data/Mono/x86$(usex amd64 "" "_64") || die
+
+	rm README~ || die
+	mv README "${T}"/ || die
+}
+
+src_install() {
+	dodoc "${T}"/README
+
+	insinto ${MYGAMEDIR}
+	doins -r *
+
+	make_desktop_entry ${PN}
+	make_wrapper ${PN} "./Splice.x86$(usex amd64 "_64" "")" "${MYGAMEDIR}"
+
+	fperms +x ${MYGAMEDIR}/Splice.x86$(usex amd64 "_64" "")
+}
diff --git a/games-puzzle/splice/splice-20121120.ebuild b/games-puzzle/splice/splice-20121120.ebuild
deleted file mode 100644
index d9b15617e47f..000000000000
--- a/games-puzzle/splice/splice-20121120.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# TODO: unbundle mono? (seems hardcoded)
-#       icon
-
-EAPI=5
-
-inherit eutils games
-
-DESCRIPTION="An experimental and artistic puzzler set in a microbial world"
-HOMEPAGE="http://www.cipherprime.com/games/splice/"
-SRC_URI="splice-linux-1353389454.tar.gz"
-
-LICENSE="all-rights-reserved"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-IUSE=""
-RESTRICT="bindist fetch splitdebug"
-
-MYGAMEDIR=${GAMES_PREFIX_OPT}/${PN}
-QA_PREBUILT="${MYGAMEDIR#/}/Splice*
-	${MYGAMEDIR#/}/Splice_Data/Mono/*"
-
-RDEPEND="
-	virtual/glu
-	virtual/opengl
-	x11-libs/libX11
-	x11-libs/libXcursor
-	x11-libs/libXext"
-
-S=${WORKDIR}/Linux
-
-pkg_nofetch() {
-	einfo "Please buy & download ${SRC_URI} from:"
-	einfo "  ${HOMEPAGE}"
-	einfo "and move it to your DISTDIR directory."
-}
-
-src_prepare() {
-	einfo "removing ${ARCH} unrelated files..."
-	rm -v Splice.x86$(usex amd64 "" "_64") || die
-	rm -rv Splice_Data/Mono/x86$(usex amd64 "" "_64") || die
-
-	rm README~ || die
-	mv README "${T}"/ || die
-}
-
-src_install() {
-	dodoc "${T}"/README
-
-	insinto "${MYGAMEDIR}"
-	doins -r *
-
-	make_desktop_entry ${PN}
-	games_make_wrapper ${PN} "./Splice.x86$(usex amd64 "_64" "")" "${MYGAMEDIR}"
-
-	fperms +x "${MYGAMEDIR}"/Splice.x86$(usex amd64 "_64" "")
-	prepgamesdirs
-}
-- 
cgit v1.2.3-65-gdbad