From cf8b49e07c8f4729742111b899f0cd1b4dbf0716 Mon Sep 17 00:00:00 2001
From: Sergey Alirzaev <zl29ah@gmail.com>
Date: Thu, 8 Jun 2017 01:44:53 +0300
Subject: games-simulation/simutrans: version bump.

Closes: https://github.com/gentoo/gentoo/pull/4882
---
 .../simutrans/simutrans-0.120.2.2.ebuild           | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 games-simulation/simutrans/simutrans-0.120.2.2.ebuild

(limited to 'games-simulation/simutrans/simutrans-0.120.2.2.ebuild')

diff --git a/games-simulation/simutrans/simutrans-0.120.2.2.ebuild b/games-simulation/simutrans/simutrans-0.120.2.2.ebuild
new file mode 100644
index 000000000000..aab9fb8ef317
--- /dev/null
+++ b/games-simulation/simutrans/simutrans-0.120.2.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic eutils
+
+MY_PV=${PV/0./}
+MY_PV=${MY_PV//./-}
+SIMUPAK="simupak64-${MY_PV%-[0-9]*}.zip"
+
+DESCRIPTION="A free Transport Tycoon clone"
+HOMEPAGE="http://www.simutrans.com/"
+SRC_URI="mirror://sourceforge/simutrans/simutrans-src-${MY_PV}.zip
+	http://simutrans-germany.com/translator/data/tab/language_pack-Base+texts.zip
+	mirror://sourceforge/simutrans/${SIMUPAK}"
+
+LICENSE="Artistic"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	sys-libs/zlib
+	app-arch/bzip2
+	media-libs/sdl-mixer
+	media-libs/libpng:0
+	media-libs/libsdl[sound,video]"
+
+DEPEND="
+	${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-Makefile.patch
+)
+
+src_unpack() {
+	unpack simutrans-src-${MY_PV}.zip
+	unpack "${SIMUPAK}"
+
+	# Bundled text files are incomplete, bug #580948
+	cd "${S}/simutrans/text" || die
+	unpack language_pack-Base+texts.zip
+}
+
+src_prepare() {
+	default
+
+	strip-flags # bug #293927
+	echo "BACKEND=mixer_sdl
+COLOUR_DEPTH=16
+OSTYPE=linux
+VERBOSE=1" > config.default || die
+
+	# make it look in the install location for the data
+	sed -i \
+		-e "s:argv\[0\]:\"/usr/share/${PN}/\":" \
+		simmain.cc || die
+
+	rm -v simutrans/{simutrans,*.txt} || die
+}
+
+src_install() {
+	newbin build/default/sim ${PN}
+	insinto /usr/share/${PN}
+	doins -r simutrans/*
+	dodoc documentation/*
+	doicon simutrans.ico
+	make_desktop_entry simutrans Simutrans /usr/share/pixmaps/simutrans.ico
+}
-- 
cgit v1.2.3