From 76ff2b559d5934237eb701ac3bfdce3975ee0b07 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Mon, 11 Feb 2019 21:17:06 +0200
Subject: gnome-extra/nm-applet: bump to 1.8.20

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 gnome-extra/nm-applet/nm-applet-1.8.20.ebuild | 66 +++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 gnome-extra/nm-applet/nm-applet-1.8.20.ebuild

(limited to 'gnome-extra/nm-applet/nm-applet-1.8.20.ebuild')

diff --git a/gnome-extra/nm-applet/nm-applet-1.8.20.ebuild b/gnome-extra/nm-applet/nm-applet-1.8.20.ebuild
new file mode 100644
index 000000000000..7e353ea1cf7c
--- /dev/null
+++ b/gnome-extra/nm-applet/nm-applet-1.8.20.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME_ORG_MODULE="network-manager-applet"
+
+inherit gnome2
+
+DESCRIPTION="GNOME applet for NetworkManager"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ayatana +introspection +gcr +modemmanager selinux teamd"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=app-crypt/libsecret-0.18
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/dbus-glib-0.88
+	>=sys-apps/dbus-1.4.1
+	>=sys-auth/polkit-0.96-r1
+	>=x11-libs/gtk+-3.10:3[introspection?]
+	>=x11-libs/libnotify-0.7.0
+
+	app-text/iso-codes
+	>=net-misc/networkmanager-1.7:=[introspection?,modemmanager?,teamd?]
+	net-misc/mobile-broadband-provider-info
+
+	ayatana? (
+		dev-libs/libappindicator:3
+		>=dev-libs/libdbusmenu-16.04.0 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	virtual/freedesktop-icon-theme
+	virtual/libgudev:=
+	gcr? ( >=app-crypt/gcr-3.14:=[gtk] )
+	modemmanager? ( net-misc/modemmanager )
+	selinux? ( sys-libs/libselinux )
+	teamd? ( >=dev-libs/jansson-2.7 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.0
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+"
+
+PDEPEND="virtual/notification-daemon" #546134
+
+src_configure() {
+	local myconf=(
+		--with-appindicator=$(usex ayatana ubuntu no)
+		--with-libnm-gtk
+		--disable-lto
+		--disable-ld-gc
+		--disable-more-warnings
+		--disable-static
+		--localstatedir=/var
+		$(use_enable introspection)
+		$(use_with gcr)
+		$(use_with modemmanager wwan)
+		$(use_with selinux)
+		$(use_with teamd team)
+	)
+	gnome2_src_configure "${myconf[@]}"
+}
-- 
cgit v1.2.3-65-gdbad