From 0b3db12de27dadd506593aa492466269cfbf0138 Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Tue, 31 Aug 2021 22:02:52 +0200
Subject: gnustep-apps/sogo: 5.2.0 bump

Also drop --disable-saml2 from configure script (similar to mfa)

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---
 gnustep-apps/sogo/Manifest          |   1 +
 gnustep-apps/sogo/sogo-5.1.1.ebuild |   1 -
 gnustep-apps/sogo/sogo-5.2.0.ebuild | 101 ++++++++++++++++++++++++++++++++++++
 3 files changed, 102 insertions(+), 1 deletion(-)
 create mode 100644 gnustep-apps/sogo/sogo-5.2.0.ebuild

(limited to 'gnustep-apps')

diff --git a/gnustep-apps/sogo/Manifest b/gnustep-apps/sogo/Manifest
index d0ebbc6a25a5..f65d6f0ed735 100644
--- a/gnustep-apps/sogo/Manifest
+++ b/gnustep-apps/sogo/Manifest
@@ -1 +1,2 @@
 DIST sogo-5.1.1.tar.gz 34263214 BLAKE2B c6a415602c931e4c703608b05036a508513eeee08d53e095ba8fa2a19ca509522ad190f8c1db78698e03818e25f221f76c097016017fc2f0aaba016043c1447e SHA512 6da4472f991da39449d8fdb05371bdc933cff8835d3501a3be475a263acb38ec10ccc43e719fb56e75fe6f5b4acd8f1f0fe3ebf1d8e734f7dbd8f28494baaff6
+DIST sogo-5.2.0.tar.gz 34444687 BLAKE2B e5b00bb9a5244086cd0ec39824f9afad0d84ef0b40e5257071a0184f9938ed88fc07654e1d136646cbf0aab08aab2492b17260933d441cfdb7d7baff3a618002 SHA512 d2ba521db1edb5c7b9901cc18f2901a1968627b5c1d535e999f321207906d44ced09fec3a9a02df9e6e4d4d315c742d253a60cc12c5c37970674fc6796e6743d
diff --git a/gnustep-apps/sogo/sogo-5.1.1.ebuild b/gnustep-apps/sogo/sogo-5.1.1.ebuild
index 9369d4e5238f..6583d3cf3d86 100644
--- a/gnustep-apps/sogo/sogo-5.1.1.ebuild
+++ b/gnustep-apps/sogo/sogo-5.1.1.ebuild
@@ -63,7 +63,6 @@ src_configure() {
 		--with-ssl="${ssl_provider}" \
 		$(use_enable debug) \
 		$(use_enable sodium) \
-		--disable-saml2 \
 		|| die "configure failed"
 }
 
diff --git a/gnustep-apps/sogo/sogo-5.2.0.ebuild b/gnustep-apps/sogo/sogo-5.2.0.ebuild
new file mode 100644
index 000000000000..6583d3cf3d86
--- /dev/null
+++ b/gnustep-apps/sogo/sogo-5.2.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnustep-2 vcs-snapshot
+
+DESCRIPTION="Groupware server built around OpenGroupware.org and the SOPE application server"
+HOMEPAGE="http://www.sogo.nu"
+SRC_URI="https://github.com/inverse-inc/sogo/archive/SOGo-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="activesync gnutls +ssl sodium"
+
+RDEPEND="
+	acct-user/sogo
+	dev-libs/libmemcached
+	net-misc/curl
+	net-misc/memcached
+	>=gnustep-libs/sope-${PV}[ldap]
+	activesync? ( dev-libs/libwbxml )
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		dev-libs/openssl:0=
+	)
+	sodium? ( dev-libs/libsodium:= )
+"
+DEPEND="${RDEPEND}
+	>=gnustep-base/gnustep-make-2.6.3"
+
+src_prepare() {
+	gnustep-base_src_prepare
+	sed -e "s/validateArgs$//" -i configure \
+		|| die
+	if use activesync; then
+		sed -e 's/Tests\/Unit/ActiveSync &/g' \
+			-i GNUmakefile || die
+	fi
+
+	default
+}
+
+src_configure() {
+	local ssl_provider
+	if use ssl ; then
+		if use gnutls ; then
+			ssl_provider=gnutls
+		else
+			ssl_provider=ssl
+		fi
+	else
+		ssl_provider=none
+	fi
+
+	egnustep_env
+
+	# saml2 requires liblasso, mfa requires liboath
+	./configure \
+		--disable-strip \
+		--prefix=/usr \
+		--with-ssl="${ssl_provider}" \
+		$(use_enable debug) \
+		$(use_enable sodium) \
+		|| die "configure failed"
+}
+
+src_install() {
+	gnustep-base_src_install
+
+	newconfd "${FILESDIR}"/sogod.confd sogod
+	newinitd "${FILESDIR}"/sogod.initd sogod
+
+	insinto /etc/logrotate.d
+	newins Scripts/logrotate sogo
+	newdoc Apache/SOGo.conf SOGo-Apache.conf
+
+	insinto /etc/sogo
+	doins Scripts/sogo.conf
+
+	insinto /etc/cron.d
+	newins Scripts/sogo.cron sogo
+	keepdir /var/log/sogo
+
+	fowners sogo:sogo /var/log/sogo
+	fowners -R root:sogo /etc/sogo
+}
+
+pkg_postinst() {
+	gnustep-base_pkg_postinst
+	elog "SOGo documentation is available online at:"
+	elog "http://www.sogo.nu/downloads/documentation.html"
+	elog
+	elog "Apache sample configuration file is available in:"
+	elog "/usr/share/doc/${PF}"
+	if use activesync; then
+		ewarn "In order to use the SOGo ActiveSync support code in production environments,"
+		ewarn "you need to get a proper usage license. Check the documentation for details."
+	fi
+}
-- 
cgit v1.2.3-65-gdbad