From 972e631fe9e658058aa0b9fa58ec2d676d1d5423 Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Sun, 22 Dec 2019 18:45:00 +0100
Subject: gnustep-apps/sogo: move to GLEP 81 users

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---
 gnustep-apps/sogo/sogo-4.1.1-r1.ebuild | 106 +++++++++++++++++++++++++++++++++
 1 file changed, 106 insertions(+)
 create mode 100644 gnustep-apps/sogo/sogo-4.1.1-r1.ebuild

(limited to 'gnustep-apps')

diff --git a/gnustep-apps/sogo/sogo-4.1.1-r1.ebuild b/gnustep-apps/sogo/sogo-4.1.1-r1.ebuild
new file mode 100644
index 000000000000..70930df687f4
--- /dev/null
+++ b/gnustep-apps/sogo/sogo-4.1.1-r1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnustep-2 vcs-snapshot
+
+DESCRIPTION="Groupware server built around OpenGroupware.org and the SOPE application server"
+HOMEPAGE="http://www.sogo.nu"
+SRC_URI="https://github.com/inverse-inc/sogo/archive/SOGo-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="activesync gnutls libressl +ssl"
+
+RDEPEND="
+	acct-user/sogo
+	dev-libs/libmemcached
+	net-misc/curl
+	net-misc/memcached
+	>=gnustep-libs/sope-${PV}[ldap]
+	activesync? ( dev-libs/libwbxml )
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	>=gnustep-base/gnustep-make-2.6.3"
+
+pkg_pretend() {
+	if use ssl && use gnutls && use libressl ; then
+		ewarn "You have enabled both gnutls and libressl, but only"
+		ewarn "one provider can be active. Using gnutls!"
+	fi
+}
+
+src_prepare() {
+	gnustep-base_src_prepare
+	sed -e "s/validateArgs$//" -i configure \
+		|| die
+	if use activesync; then
+		sed -e 's/Tests\/Unit/ActiveSync &/g' \
+			-i GNUmakefile || die
+	fi
+
+	default
+}
+
+src_configure() {
+	local ssl_provider
+	if use ssl ; then
+		if use gnutls ; then
+			ssl_provider=gnutls
+		else
+			ssl_provider=ssl
+		fi
+	else
+		ssl_provider=none
+	fi
+
+	egnustep_env
+
+	./configure \
+		--disable-strip \
+		--prefix=/usr \
+		--with-ssl="${ssl_provider}" \
+		$(use_enable debug) \
+		|| die "configure failed"
+}
+
+src_install() {
+	gnustep-base_src_install
+
+	newconfd "${FILESDIR}"/sogod.confd sogod
+	newinitd "${FILESDIR}"/sogod.initd sogod
+
+	insinto /etc/logrotate.d
+	newins Scripts/logrotate sogo
+	newdoc Apache/SOGo.conf SOGo-Apache.conf
+
+	insinto /etc/sogo
+	doins Scripts/sogo.conf
+
+	insinto /etc/cron.d
+	newins Scripts/sogo.cron sogo
+	keepdir /var/log/sogo
+
+	fowners sogo:sogo /var/log/sogo
+	fowners -R root:sogo /etc/sogo
+}
+
+pkg_postinst() {
+	gnustep-base_pkg_postinst
+	elog "SOGo documentation is available online at:"
+	elog "http://www.sogo.nu/downloads/documentation.html"
+	elog
+	elog "Apache sample configuration file is available in:"
+	elog "/usr/share/doc/${PF}"
+	if use activesync; then
+		ewarn "In order to use the SOGo ActiveSync support code in production environments,"
+		ewarn "you need to get a proper usage license. Check the documentation for details."
+	fi
+}
-- 
cgit v1.2.3-65-gdbad