From 78cd57b5bcec438e01ab64e5aa379d07a6c83410 Mon Sep 17 00:00:00 2001
From: Aisha Tammy <gentoo@aisha.cc>
Date: Sat, 30 Jan 2021 03:09:14 +0000
Subject: gui-wm/wayfire: version bump to 0.7.0

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Aisha Tammy <gentoo@aisha.cc>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 gui-wm/wayfire/Manifest             |  1 +
 gui-wm/wayfire/wayfire-0.7.0.ebuild | 98 +++++++++++++++++++++++++++++++++++++
 gui-wm/wayfire/wayfire-9999.ebuild  |  4 +-
 3 files changed, 101 insertions(+), 2 deletions(-)
 create mode 100644 gui-wm/wayfire/wayfire-0.7.0.ebuild

(limited to 'gui-wm')

diff --git a/gui-wm/wayfire/Manifest b/gui-wm/wayfire/Manifest
index f705f3f30439..5d3e75680efe 100644
--- a/gui-wm/wayfire/Manifest
+++ b/gui-wm/wayfire/Manifest
@@ -1,2 +1,3 @@
 DIST wayfire-0.5.0.tar.xz 670680 BLAKE2B 6a1555669352dd1303f7472db4fbb8ada6173c09825f4e999a2862787bd5bf31e070e9e12110249b9407d8c380235f4a9d3c5be6b23defe36094822526eed6ef SHA512 9c2d116a5d6e77e37b0e4eef26624d43d6ab3a80e56e19a2de1fdd28a2a522c24b9e346eb4529848f3b2c3668460a51f428a0c196286ec8300e4823250eae811
 DIST wayfire-0.6.0.tar.xz 701084 BLAKE2B 3ee0274c706aaa4690e9eb9617d2f272dd1e6573529c40b43d3fd05e79a4ddceef8dec34a7d2363aff8603fb3fd7490c4d2e79e67bff825a3bb68cc8090ad301 SHA512 dc6b5378dc51352ab41ac3c5713e73f341caa2a119a91826818b0a7cde629e63ce855a4376b5c60b468717336dda4806fb1195d534cd7ab2e5d6285c8075102e
+DIST wayfire-0.7.0.tar.xz 735756 BLAKE2B 8298cc92938f5196e3dc5bac39d4d9db370e69209461feb5d7abe685e0277efd4bd42ef2c18dc41d79e20d794dae5889efec56f8278fde6efc37b8017c5e65ea SHA512 eaaa193619a6cb0c7a0879aa24a7f6d468e81aeef0b9f17a282f5f930c00557a021f4d45de4aae6f57ce5e427148387c3fdf344ea9c6843a75e777eeeeb96f79
diff --git a/gui-wm/wayfire/wayfire-0.7.0.ebuild b/gui-wm/wayfire/wayfire-0.7.0.ebuild
new file mode 100644
index 000000000000..339de620d255
--- /dev/null
+++ b/gui-wm/wayfire/wayfire-0.7.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="compiz like 3D wayland compositor"
+HOMEPAGE="https://github.com/WayfireWM/wayfire"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/WayfireWM/${PN}.git"
+else
+	SRC_URI="https://github.com/WayfireWM/${PN}/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+gles +system-wfconfig +system-wlroots elogind systemd X"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	dev-libs/libevdev
+	dev-libs/libinput
+	gui-libs/gtk-layer-shell
+	media-libs/glm
+	media-libs/mesa:=[gles2,wayland,X?]
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/freetype:=[X?]
+	x11-libs/libdrm
+	x11-libs/gtk+:3=[wayland,X?]
+	x11-libs/cairo:=[X?,svg]
+	X? ( x11-libs/libxkbcommon:=[X] )
+	x11-libs/pixman
+	gles? ( media-libs/libglvnd[X?] )
+	system-wfconfig? ( >=gui-libs/wf-config-${PV%.*} )
+	!system-wfconfig? ( !gui-libs/wf-config )
+	system-wlroots? ( >=gui-libs/wlroots-0.12.0[elogind=,systemd=,X?] )
+	!system-wlroots? ( !gui-libs/wlroots )
+"
+
+RDEPEND="
+	${DEPEND}
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+	x11-misc/xkeyboard-config
+"
+
+BDEPEND="
+	dev-libs/wayland-protocols
+	virtual/pkgconfig
+"
+
+src_configure() {
+	sed -e "s:@EPREFIX@:${EPREFIX}:" \
+	    "${FILESDIR}"/wayfire-session > "${T}"/wayfire-session || die
+	sed -e "s:@EPREFIX@:${EPREFIX}:" \
+	    "${FILESDIR}"/wayfire-session.desktop > "${T}"/wayfire-session.desktop || die
+	local emesonargs=(
+		$(meson_feature system-wfconfig use_system_wfconfig)
+		$(meson_feature system-wlroots use_system_wlroots)
+		$(meson_feature X xwayland)
+		$(meson_use gles enable_gles32)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	default
+	meson_src_install
+	dobin "${T}"/wayfire-session
+	einstalldocs
+
+	insinto "/usr/share/wayland-sessions/"
+	insopts -m644
+	doins wayfire.desktop
+	doins "${T}"/wayfire-session.desktop
+
+	dodoc wayfire.ini
+
+	if ! use systemd && ! use elogind; then
+		fowners root:0 /usr/bin/wayfire
+		fperms 4511 /usr/bin/wayfire
+	fi
+}
+
+pkg_postinst() {
+	if [ -z "${REPLACING_VERSIONS}" ]; then
+		elog "Wayfire has been installed but the session cannot be used"
+		elog "until you install a configuration file. The default config"
+		elog "file is installed at \"/usr/share/doc/${PF}/wayfire.ini.bz2\""
+		elog "To install the file execute"
+		elog "\$ mkdir -p ~/.config && bzcat /usr/share/doc/${PF}/wayfire.ini.bz2 > ~/.config/wayfire.ini"
+	fi
+}
diff --git a/gui-wm/wayfire/wayfire-9999.ebuild b/gui-wm/wayfire/wayfire-9999.ebuild
index 96f551ce51ca..339de620d255 100644
--- a/gui-wm/wayfire/wayfire-9999.ebuild
+++ b/gui-wm/wayfire/wayfire-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2019-2020 Gentoo Authors
+# Copyright 2019-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/WayfireWM/${PN}.git"
 else
-	SRC_URI="https://github.com/WayfireWM/${PN}/releases/download/${PV}/${P}.tar.xz"
+	SRC_URI="https://github.com/WayfireWM/${PN}/releases/download/v${PV}/${P}.tar.xz"
 	KEYWORDS="~amd64 ~arm64 ~x86"
 fi
 
-- 
cgit v1.2.3-65-gdbad