From 2bc5a0c0d8acb0b9ba189e38d9f335455a77bd8d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 22 Apr 2023 10:12:58 +0200
Subject: kde-apps/akonadi: 23.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/akonadi/Manifest               |   1 +
 kde-apps/akonadi/akonadi-23.04.0.ebuild | 124 ++++++++++++++++++++++++++++++++
 2 files changed, 125 insertions(+)
 create mode 100644 kde-apps/akonadi/akonadi-23.04.0.ebuild

(limited to 'kde-apps/akonadi')

diff --git a/kde-apps/akonadi/Manifest b/kde-apps/akonadi/Manifest
index f0f257276ce9..3230273b169c 100644
--- a/kde-apps/akonadi/Manifest
+++ b/kde-apps/akonadi/Manifest
@@ -1 +1,2 @@
 DIST akonadi-22.12.3.tar.xz 1661668 BLAKE2B d4ec74a56e248b8b0330d7c0ff50d84a56a2aff89bf62f794e6ac413f444d1290da92eff3a0f321f19bf86844c6465b284a85f361cc9a651cf7c008d212a1a2b SHA512 84a519d2d4d600c1ebcf9b90b33b2733a327b48914b0115613d2ba9fb44c85e76ea3c56f220b1c76e66a60a4ebbc26c10ee94c34f23e0417e47e0f48cb91b6e6
+DIST akonadi-23.04.0.tar.xz 1667996 BLAKE2B 3af8d63bdfe1e353eeaab580683105c741ba7310b8d794ce317d29e37fff8cf4b14e0d2c1143a309b110c8ac2f1807a6f757232108ba055f30ef3bf0e860d9a6 SHA512 31dc51b25da7f3f4ea2c8ef2bf6ac15fa132e94176bb2d1e38716991fc904d0a2a28ad575847dafe9089a5e44b7f0326314b0cabb4593f35930724155da6436a
diff --git a/kde-apps/akonadi/akonadi-23.04.0.ebuild b/kde-apps/akonadi/akonadi-23.04.0.ebuild
new file mode 100644
index 000000000000..5b3c61ffb002
--- /dev/null
+++ b/kde-apps/akonadi/akonadi-23.04.0.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_DESIGNERPLUGIN="true"
+ECM_QTHELP="true"
+ECM_TEST="forceoptional"
+KFMIN=5.104.0
+QTMIN=5.15.5
+VIRTUALDBUS_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org readme.gentoo-r1
+
+DESCRIPTION="Storage service for PIM data and libraries for PIM apps"
+HOMEPAGE="https://community.kde.org/KDE_PIM/akonadi"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+kaccounts +mysql postgres sqlite tools xml"
+
+REQUIRED_USE="|| ( mysql postgres sqlite ) test? ( tools )"
+
+# some akonadi tests time out, that probably needs more work as it's ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	app-arch/xz-utils
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[mysql?,postgres?]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-20.08.3:5
+		>=net-libs/accounts-qt-1.16
+	)
+	sqlite? (
+		dev-db/sqlite:3
+		>=dev-qt/qtsql-${QTMIN}:5=[sqlite]
+	)
+	xml? ( dev-libs/libxml2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${COMMON_DEPEND}
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.03.80-mysql56-crash.patch" )
+
+pkg_setup() {
+	# Set default storage backend in order: MySQL, PostgreSQL, SQLite
+	# reverse driver check to keep the order
+	use sqlite && DRIVER="QSQLITE3"
+	use postgres && DRIVER="QPSQL"
+	use mysql && DRIVER="QMYSQL"
+
+	if use mysql && has_version "${CATEGORY}/${PN}[mysql]" && has_version "dev-db/mariadb"; then
+		ewarn
+		ewarn "Attention: Make sure to read README.gentoo after install."
+		ewarn
+	fi
+
+	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
+		ewarn "We strongly recommend you change your Akonadi database backend to"
+		ewarn "either MariaDB/MySQL or PostgreSQL in your user configuration."
+		ewarn "In particular, kde-apps/kmail does not work properly with the sqlite backend."
+	fi
+
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		-DAKONADI_BUILD_QSQLITE=$(usex sqlite)
+		-DBUILD_TOOLS=$(usex tools)
+		$(cmake_use_find_package xml LibXml2)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	# Who knows, maybe it accidentally fixes our permission issues
+	cat <<-EOF > "${T}"/akonadiserverrc
+[%General]
+Driver=${DRIVER}
+EOF
+	insinto /usr/share/config/akonadi
+	doins "${T}"/akonadiserverrc
+
+	ecm_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "You can select the storage backend in ~/.config/akonadi/akonadiserverrc."
+	elog "Available drivers are:"
+	use mysql && elog "  QMYSQL"
+	use postgres && elog "  QPSQL"
+	use sqlite && elog "  QSQLITE3"
+	elog "${DRIVER} has been set as your default akonadi storage backend."
+	use mysql && elog
+	use mysql && FORCE_PRINT_ELOG=1 readme.gentoo_print_elog
+}
-- 
cgit v1.2.3-65-gdbad