From f20e29ce68aae40c5532f23fa97fdeb512289535 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 21 Jul 2022 11:59:08 +0200
Subject: kde-misc/kio-gdrive: Drop IUSE=kaccounts

Google Account authentication is currently broken at runtime without
kaccounts integration, and qtkeychain backend code is getting increasingly
crusty with build broken in >=22.07.80 as well. Reported upstream and
option disabled until fixed there.

This gets rid of REQUIRED_USE and makes this logically sound to be hidden
behind IUSE=webengine within kdenetwork-meta because of
kde-apps/kaccounts-providers hard-depending on dev-qt/qtwebengine.

KDE-bug: https://bugs.kde.org/show_bug.cgi?id=439639
KDE-bug: https://bugs.kde.org/show_bug.cgi?id=456975

Bug: https://bugs.gentoo.org/782505
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-misc/kio-gdrive/kio-gdrive-22.04.3-r1.ebuild | 48 ++++++++++++++++++++++
 kde-misc/kio-gdrive/kio-gdrive-22.04.3.ebuild    | 52 ------------------------
 kde-misc/kio-gdrive/metadata.xml                 |  1 -
 3 files changed, 48 insertions(+), 53 deletions(-)
 create mode 100644 kde-misc/kio-gdrive/kio-gdrive-22.04.3-r1.ebuild
 delete mode 100644 kde-misc/kio-gdrive/kio-gdrive-22.04.3.ebuild

(limited to 'kde-misc/kio-gdrive')

diff --git a/kde-misc/kio-gdrive/kio-gdrive-22.04.3-r1.ebuild b/kde-misc/kio-gdrive/kio-gdrive-22.04.3-r1.ebuild
new file mode 100644
index 000000000000..95142c9693b9
--- /dev/null
+++ b/kde-misc/kio-gdrive/kio-gdrive-22.04.3-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KDE_GEAR="true"
+KDE_ORG_CATEGORY="network"
+KFMIN=5.92.0
+QTMIN=5.15.4
+inherit ecm gear.kde.org
+
+DESCRIPTION="KIO worker for Google Drive service"
+HOMEPAGE="https://apps.kde.org/kio_gdrive/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="amd64 arm64 ~ppc64 ~x86"
+IUSE="+share"
+
+COMMON_DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kaccounts-integration-20.08.3:5
+	>=kde-apps/libkgapi-19.08.0:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtnetwork-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-apps/kaccounts-providers-20.08.3:5
+"
+BDEPEND="dev-util/intltool"
+
+DOCS=( README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}
diff --git a/kde-misc/kio-gdrive/kio-gdrive-22.04.3.ebuild b/kde-misc/kio-gdrive/kio-gdrive-22.04.3.ebuild
deleted file mode 100644
index ba640924c51e..000000000000
--- a/kde-misc/kio-gdrive/kio-gdrive-22.04.3.ebuild
+++ /dev/null
@@ -1,52 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="optional"
-KDE_GEAR="true"
-KDE_ORG_CATEGORY="network"
-KFMIN=5.92.0
-QTMIN=5.15.4
-inherit ecm gear.kde.org
-
-DESCRIPTION="KIO Slave for Google Drive service"
-HOMEPAGE="https://apps.kde.org/kio_gdrive/"
-
-LICENSE="GPL-2+"
-SLOT="5"
-KEYWORDS="amd64 arm64 ~ppc64 ~x86"
-IUSE="+kaccounts +share"
-
-REQUIRED_USE="share? ( kaccounts )"
-
-COMMON_DEPEND="
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-apps/libkgapi-19.08.0:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	kaccounts? ( >=kde-apps/kaccounts-integration-20.08.3:5 )
-	!kaccounts? ( dev-libs/qtkeychain:=[qt5(+)] )
-	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-qt/qtnetwork-${QTMIN}:5
-"
-RDEPEND="${COMMON_DEPEND}
-	kaccounts? ( >=kde-apps/kaccounts-providers-20.08.3:5 )
-"
-BDEPEND="dev-util/intltool"
-
-DOCS=( README.md )
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package kaccounts KAccounts)
-		$(cmake_use_find_package share KF5Purpose)
-	)
-	ecm_src_configure
-}
diff --git a/kde-misc/kio-gdrive/metadata.xml b/kde-misc/kio-gdrive/metadata.xml
index 35ead628e97b..8213019cba2d 100644
--- a/kde-misc/kio-gdrive/metadata.xml
+++ b/kde-misc/kio-gdrive/metadata.xml
@@ -9,7 +9,6 @@
 		<bugs-to>https://bugs.kde.org/</bugs-to>
 	</upstream>
 	<use>
-		<flag name="kaccounts">Use <pkg>kde-apps/kaccounts-integration</pkg> backend (default) instead of <pkg>dev-libs/qtkeychain</pkg></flag>
 		<flag name="share">Enable support for a share menu using <pkg>kde-frameworks/purpose</pkg></flag>
 	</use>
 </pkgmetadata>
-- 
cgit v1.2.3-65-gdbad