From 4b45af431015b96b5222fb23688c28262828f77e Mon Sep 17 00:00:00 2001
From: Dirkjan Ochtman <djc@gentoo.org>
Date: Fri, 24 Feb 2017 13:32:29 +0100
Subject: mail-filters/rspamd: version bump to 1.4.4 (fixes bug 610430)

Package-Manager: portage-2.3.3
---
 mail-filter/rspamd/rspamd-1.4.4.ebuild | 74 ++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 mail-filter/rspamd/rspamd-1.4.4.ebuild

(limited to 'mail-filter/rspamd/rspamd-1.4.4.ebuild')

diff --git a/mail-filter/rspamd/rspamd-1.4.4.ebuild b/mail-filter/rspamd/rspamd-1.4.4.ebuild
new file mode 100644
index 00000000000..10d0ba28fc1
--- /dev/null
+++ b/mail-filter/rspamd/rspamd-1.4.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils pax-utils user systemd
+
+DESCRIPTION="Rapid spam filtering system"
+SRC_URI="https://rspamd.com/downloads/${P}.tar.xz"
+HOMEPAGE="https://github.com/vstakhov/rspamd"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="fann jemalloc +jit libressl pcre2"
+
+RDEPEND="!libressl? ( dev-libs/openssl:0=[-bindist] )
+	libressl? ( dev-libs/libressl:0= )
+	fann? ( sci-mathematics/fann )
+	pcre2? ( dev-libs/libpcre2[jit=] )
+	!pcre2? ( dev-libs/libpcre[jit=] )
+	jit? ( dev-lang/luajit:2 )
+	jemalloc? ( dev-libs/jemalloc )
+	dev-libs/libevent
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/gmime
+	<dev-util/ragel-7.0
+	sys-apps/file
+	virtual/libiconv"
+DEPEND="dev-util/ragel
+	${RDEPEND}"
+
+QA_MULTILIB_PATHS="usr/lib/rspamd/.*"
+
+pkg_setup() {
+	enewgroup rspamd
+	enewuser rspamd -1 -1 /var/lib/rspamd rspamd
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFDIR=/etc/rspamd
+		-DRUNDIR=/var/run/rspamd
+		-DDBDIR=/var/lib/rspamd
+		-DLOGDIR=/var/log/rspamd
+		-DENABLE_LUAJIT=$(usex jit ON OFF)
+		-DENABLE_FANN=$(usex fann ON OFF)
+		-DENABLE_PCRE2=$(usex pcre2 ON OFF)
+		-DENABLE_JEMALLOC=$(usex jemalloc ON OFF)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newinitd "${FILESDIR}/rspamd.init-r2" rspamd
+
+	# Remove mprotect for JIT support
+	if use jit; then
+		pax-mark m "${ED}"/usr/bin/rspamd-* "${ED}"/usr/bin/rspamadm-* || die
+	fi
+
+	dodir /var/lib/rspamd
+	dodir /var/log/rspamd
+
+	fowners rspamd:rspamd /var/lib/rspamd /var/log/rspamd
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/rspamd.logrotate" rspamd
+
+	systemd_newunit rspamd.service rspamd.service
+}
-- 
cgit v1.2.3