From b9323653f6240231f61bd7e9835264dfb3996fc9 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Sat, 31 Mar 2018 00:52:18 -0400
Subject: media-gfx/libimagequant: version bump to 2.11.7

---
 .../libimagequant/libimagequant-2.11.7.ebuild      | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 media-gfx/libimagequant/libimagequant-2.11.7.ebuild

(limited to 'media-gfx/libimagequant/libimagequant-2.11.7.ebuild')

diff --git a/media-gfx/libimagequant/libimagequant-2.11.7.ebuild b/media-gfx/libimagequant/libimagequant-2.11.7.ebuild
new file mode 100644
index 000000000000..2d2db96f010b
--- /dev/null
+++ b/media-gfx/libimagequant/libimagequant-2.11.7.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Palette quantization library that powers pngquant and other PNG optimizers"
+HOMEPAGE="https://pngquant.org/lib/"
+SRC_URI="https://github.com/ImageOptim/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cpu_flags_x86_sse2 debug openmp static-libs"
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	tc-export AR CC
+	# Hand rolled configure script, so not all flags are supported.
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		$(use debug && echo --enable-debug) \
+		$(use_enable cpu_flags_x86_sse2 sse) \
+		$(use_with openmp) \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_compile() {
+	emake shared || die "make failed"
+	use static-libs && (emake static || die "make failed")
+}
+
+src_install() {
+	dolib.so libimagequant.so
+	dolib.so libimagequant.so.*
+	use static-libs && dolib.a libimagequant.a
+	doheader libimagequant.h
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad