From 535ad6c81205775104b3a149542ac707d8534a45 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Wed, 29 Apr 2020 23:07:26 +0300
Subject: media-gfx/simple-scan: bump to 3.34.6

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 media-gfx/simple-scan/Manifest                  |  1 +
 media-gfx/simple-scan/simple-scan-3.34.6.ebuild | 70 +++++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 media-gfx/simple-scan/simple-scan-3.34.6.ebuild

(limited to 'media-gfx/simple-scan')

diff --git a/media-gfx/simple-scan/Manifest b/media-gfx/simple-scan/Manifest
index 82db67e594f8..b1314cdd2c78 100644
--- a/media-gfx/simple-scan/Manifest
+++ b/media-gfx/simple-scan/Manifest
@@ -1 +1,2 @@
 DIST simple-scan-3.34.4.tar.xz 795228 BLAKE2B b6f185bfbc1954ae2573fd1dcfa54f67e26290654c1019bfd34c229235e27cfc1eb40de0e6d5249f97b73c57745e1133fbd6fd1c3f9bdedb795b61068d5ed25d SHA512 b16b653e0a8ce399ecbdb88c4663d7780793518809eb73681c9c6281b9cde784167090c41720b21c184b9fdece28b07ba61fe8a97f10d792cc7326a458741ba4
+DIST simple-scan-3.34.6.tar.xz 801064 BLAKE2B 94c6bc386c2d7701bd13067e384eb294ce145d2e02d66e366e76a2c85fb5e3ac4e9bae0efa37fe13d3fc857b57c1730bf01961f7968d6744a4ea4dc47308cb23 SHA512 7b2d0eab13f08d4110d2143c4572e249297891e3868e6eb178a7a765b2d56960820931fbda538ede318014c578871657aa0e27518d184f861efc18ad4fdd900c
diff --git a/media-gfx/simple-scan/simple-scan-3.34.6.ebuild b/media-gfx/simple-scan/simple-scan-3.34.6.ebuild
new file mode 100644
index 000000000000..a2e99a48eaa5
--- /dev/null
+++ b/media-gfx/simple-scan/simple-scan-3.34.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.34"
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="colord webp"
+
+DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.22:3
+	>=sys-libs/zlib-1.2.3.1:=
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/libgusb-0.2.7
+	colord? ( >=x11-misc/colord-0.1.24:=[udev] )
+	webp? ( media-libs/libwebp )
+	>=media-gfx/sane-backends-1.0.20:=
+
+	virtual/jpeg:0=
+"
+# packagekit? ( >=app-admin/packagekit-base-1.1.5 )
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	dev-libs/libgusb[vala]
+	colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+	# Add control for optional dependencies
+	"${FILESDIR}"/3.26-add-control-optional-deps.patch
+)
+
+src_prepare() {
+	vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord)
+		-Dpackagekit=false
+		$(meson_use webp)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad