From 1add15c165f0a79729e3f90797284b619ead8989 Mon Sep 17 00:00:00 2001
From: Dennis Lamm <expeditioneer@gentoo.org>
Date: Sun, 11 Oct 2020 16:19:36 +0200
Subject: media-gfx/slic3r: fixed .desktop file

Closes: https://bugs.gentoo.org/712898

Signed-off-by: Dennis Lamm <expeditoneer@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/17888
Signed-off-by: Dennis Lamm <expeditioneer@gentoo.org>
---
 media-gfx/slic3r/slic3r-1.3.0-r2.ebuild | 118 ++++++++++++++++++++++++++++++++
 media-gfx/slic3r/slic3r-9999.ebuild     |   2 +-
 2 files changed, 119 insertions(+), 1 deletion(-)
 create mode 100644 media-gfx/slic3r/slic3r-1.3.0-r2.ebuild

(limited to 'media-gfx')

diff --git a/media-gfx/slic3r/slic3r-1.3.0-r2.ebuild b/media-gfx/slic3r/slic3r-1.3.0-r2.ebuild
new file mode 100644
index 000000000000..60c8950aab45
--- /dev/null
+++ b/media-gfx/slic3r/slic3r-1.3.0-r2.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic perl-module
+
+DESCRIPTION="A mesh slicer to generate G-code for fused-filament-fabrication (3D printers)"
+HOMEPAGE="https://slic3r.org"
+SRC_URI="https://github.com/alexrj/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="AGPL-3 CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gui test"
+RESTRICT="!test? ( test )"
+
+# check Build.PL for dependencies
+RDEPEND="!=dev-lang/perl-5.16*
+	>=dev-libs/boost-1.55[threads]
+	dev-perl/Class-XSAccessor
+	dev-perl/Devel-CheckLib
+	dev-perl/Devel-Size
+	>=dev-perl/Encode-Locale-1.50.0
+	dev-perl/IO-stringy
+	>=dev-perl/Math-PlanePath-53.0.0
+	>=dev-perl/Moo-1.3.1
+	dev-perl/XML-SAX-ExpatXS
+	virtual/perl-Carp
+	virtual/perl-Encode
+	virtual/perl-File-Spec
+	virtual/perl-Getopt-Long
+	virtual/perl-parent
+	virtual/perl-Scalar-List-Utils
+	virtual/perl-Test-Simple
+	virtual/perl-Thread-Semaphore
+	>=virtual/perl-threads-1.960.0
+	virtual/perl-Time-HiRes
+	virtual/perl-Unicode-Normalize
+	virtual/perl-XSLoader
+	gui? ( dev-perl/Class-Accessor
+		dev-perl/Growl-GNTP
+		dev-perl/libwww-perl
+		dev-perl/Module-Pluggable
+		dev-perl/Net-Bonjour
+		dev-perl/Net-DBus
+		dev-perl/OpenGL
+		>=dev-perl/Wx-0.991.800
+		dev-perl/Wx-GLCanvas
+		>=media-libs/freeglut-3
+		virtual/perl-Math-Complex
+		>=virtual/perl-Socket-2.16.0
+		x11-libs/libXmu
+	)"
+DEPEND="${RDEPEND}
+	dev-perl/Devel-CheckLib
+	>=dev-perl/ExtUtils-CppGuess-0.70.0
+	>=dev-perl/ExtUtils-Typemaps-Default-1.50.0
+	>=dev-perl/ExtUtils-XSpp-0.170.0
+	>=dev-perl/Module-Build-0.380.0
+	>=dev-perl/Module-Build-WithXSpp-0.140.0
+	>=virtual/perl-ExtUtils-MakeMaker-6.800.0
+	>=virtual/perl-ExtUtils-ParseXS-3.220.0
+	test? (	virtual/perl-Test-Harness
+		virtual/perl-Test-Simple )"
+
+S="${WORKDIR}/Slic3r-${PV}/xs"
+
+pkg_pretend() {
+	einfo "Checking for -std=c++11 support in compiler"
+	test-flags-CXX -std=c++11 > /dev/null || die
+}
+
+src_prepare() {
+	pushd "${WORKDIR}/Slic3r-${PV}" || die
+	sed -i lib/Slic3r.pm -e "s@FindBin::Bin@FindBin::RealBin@g" || die
+	eapply "${FILESDIR}"/${P}-no-locallib.patch
+	eapply "${FILESDIR}"/${P}-boost.patch
+	eapply_user
+	popd || die
+	# drop std=c++11 to compiler defaults...
+	sed \
+		-e '/c++11/d' \
+		-i Build.PL || die
+}
+
+src_configure() {
+	SLIC3R_NO_AUTO=1 perl-module_src_configure
+}
+
+src_test() {
+	perl-module_src_test
+	pushd .. || die
+	prove -Ixs/blib/arch -Ixs/blib/lib/ t/ || die "Tests failed"
+	popd || die
+}
+
+src_install() {
+	perl-module_src_install
+
+	pushd .. || die
+	insinto "${VENDOR_LIB}"
+	doins -r lib/Slic3r.pm lib/Slic3r
+
+	insinto "${VENDOR_LIB}"/Slic3r
+	doins -r var
+
+	exeinto "${VENDOR_LIB}"/Slic3r
+	doexe slic3r.pl
+
+	dosym "${VENDOR_LIB}"/Slic3r/slic3r.pl /usr/bin/slic3r.pl
+
+	make_desktop_entry "slic3r.pl --gui %F" \
+		Slic3r \
+		"${VENDOR_LIB}/Slic3r/var/Slic3r_128px.png" \
+		"Graphics;3DGraphics;Engineering;Development"
+	popd || die
+}
diff --git a/media-gfx/slic3r/slic3r-9999.ebuild b/media-gfx/slic3r/slic3r-9999.ebuild
index 61ef1b641af8..404994de740e 100644
--- a/media-gfx/slic3r/slic3r-9999.ebuild
+++ b/media-gfx/slic3r/slic3r-9999.ebuild
@@ -106,7 +106,7 @@ src_install() {
 
 	dosym "${VENDOR_LIB}"/Slic3r/slic3r.pl /usr/bin/slic3r.pl
 
-	make_desktop_entry slic3r.pl \
+	make_desktop_entry "slic3r.pl --gui %F" \
 		Slic3r \
 		"${VENDOR_LIB}/Slic3r/var/Slic3r_128px.png" \
 		"Graphics;3DGraphics;Engineering;Development"
-- 
cgit v1.2.3-65-gdbad