From c0405a099cdb8f8f35578fbee4a09e60f5e53028 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Fri, 6 Oct 2017 09:29:08 +0200
Subject: media-libs/aubio: Bump to version 0.4.6

Package-Manager: Portage-2.3.11, Repoman-2.3.3
---
 media-libs/aubio/Manifest           |   1 +
 media-libs/aubio/aubio-0.4.6.ebuild | 110 ++++++++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)
 create mode 100644 media-libs/aubio/aubio-0.4.6.ebuild

(limited to 'media-libs/aubio')

diff --git a/media-libs/aubio/Manifest b/media-libs/aubio/Manifest
index 9e08e5925220..34a48c1434da 100644
--- a/media-libs/aubio/Manifest
+++ b/media-libs/aubio/Manifest
@@ -3,3 +3,4 @@ DIST aubio-0.4.2.tar.bz2 304216 SHA256 1cc58e0fed2b9468305b198ad06b889f228b797a0
 DIST aubio-0.4.3.tar.bz2 328852 SHA256 b62cdb073c0c64ae301917fa162969d42cba45e478bdf1e74490bd87e9cceaab SHA512 bc286f1af9bc23e8bb5e4fa49a1d392e4f8169b8ca59409ee79bbbebf887f60ac7f68a6ed465272dbfc46f8c1ebf902513428e67cab5b88c4500ffe93f1c21d5 WHIRLPOOL 260e63d3f32a18fef104dfdf175ac7a864b701048fbaa0fc3005dde6058df45ab66329401a3a47e80df407340b8ab6bb13ceda49510d1860c8302720ec55e3e2
 DIST aubio-0.4.4.tar.bz2 334754 SHA256 2acdb92623b9d4ba641c387760ffe3ec1e4c6ab498e64e5e2286c99e36ffbff8 SHA512 ddf9019117b5da752eaf74bee0e5ba51d758f41b4e5a2ea64773fc3332c930c7215235b2ceb58bcb73e04811a3367efe19a606aee76d328a4d9670db82608d83 WHIRLPOOL b91b9de9dd5ac244c0f05fa8ba6e8e3e57ffd563d026f5b3834c9eff0eca9a6bbec3eb795fd2738a3a3f53a47a210648aa3893cd8684be187755c2c036a175d6
 DIST aubio-0.4.5.tar.bz2 350615 SHA256 70c2804e6f4fbf0ebc0fb9ac8cc9d465ef4a4d438311c074c9a7364e98827af6 SHA512 0aeaee5efc117201ca7b1fe2a421826ade83ce5b3ba50c27a8cf65debeedb20dd5a5ac28e20935bb29ca2b0d1b70cf93feee298989dfc79978f689e989235608 WHIRLPOOL b70d452570d1fc8b7168eac5bca3ce150aa33f24576815efa685cffef60511fa3e259c233c8f3d99ae5f88a6d8e94d4686a040912948c3783323eceec202a843
+DIST aubio-0.4.6.tar.bz2 363016 SHA256 bdc73be1f007218d3ea6d2a503b38a217815a0e2ccc4ed441f6e850ed5d47cfb SHA512 0e5cab0c88d51f2fb70c0d85e1c067a7b3758fbffdbd5026686726379aa36203adb63ed3f8e40c83ea02930e0ffc4e6c246803f1d518d448d47a01984678e77d WHIRLPOOL 3c1a789d4103681ed005fa4d10aa6b8e3515c2b46a6dc6584e8c94e701dd681fd8fe3561809a9bdaf41c2e3605b2da8d3f19f331825102ff2cf84a1995c7da65
diff --git a/media-libs/aubio/aubio-0.4.6.ebuild b/media-libs/aubio/aubio-0.4.6.ebuild
new file mode 100644
index 000000000000..c02467cd6e71
--- /dev/null
+++ b/media-libs/aubio/aubio-0.4.6.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+)'
+
+inherit distutils-r1 waf-utils multilib eutils
+
+DESCRIPTION="Library for audio labelling"
+HOMEPAGE="https://aubio.org/"
+SRC_URI="https://aubio.org/pub/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0/5"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc double-precision examples ffmpeg fftw jack libav libsamplerate sndfile python"
+
+RDEPEND="
+	ffmpeg? (
+		!libav? ( >=media-video/ffmpeg-2.6:0= )
+		libav? ( >=media-video/libav-9:0= )
+	)
+	fftw? ( sci-libs/fftw:3.0 )
+	jack? ( virtual/jack )
+	libsamplerate? ( media-libs/libsamplerate )
+	python? ( dev-python/numpy[${PYTHON_USEDEP}] ${PYTHON_DEPS} )
+	sndfile? ( media-libs/libsndfile )
+"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	app-text/txt2man
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS ChangeLog README.md )
+PYTHON_SRC_DIR="${S}"
+
+src_prepare() {
+	default
+	sed -i -e "s:doxygen:doxygen_disabled:" wscript || die
+}
+
+src_configure() {
+	python_setup
+	waf-utils_src_configure \
+		--enable-complex \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable double-precision double) \
+		$(use_enable fftw fftw3f) \
+		$(use_enable fftw fftw3) \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable sndfile)
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	waf-utils_src_compile --notests
+
+	if use doc; then
+		cd "${S}"/doc || die
+		emake dirhtml
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	waf-utils_src_compile --alltests
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_test
+	fi
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use examples; then
+		# install dist_noinst_SCRIPTS from Makefile.am
+		dodoc -r examples
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		DOCS="" distutils-r1_src_install
+		newdoc python/README.md README.python
+	fi
+
+	if use doc; then
+		dodoc doc/*.txt
+		docinto html
+		dodoc -r doc/_build/dirhtml/.
+	fi
+}
-- 
cgit v1.2.3-65-gdbad