From ffa2e5584838ec6c73b46297f4844efd1626a882 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Thu, 8 Mar 2018 11:20:49 +0100
Subject: media-libs/fdk-aac: Bump to version 0.1.6

Package-Manager: Portage-2.3.24, Repoman-2.3.6
---
 media-libs/fdk-aac/Manifest             |  1 +
 media-libs/fdk-aac/fdk-aac-0.1.6.ebuild | 56 +++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 media-libs/fdk-aac/fdk-aac-0.1.6.ebuild

(limited to 'media-libs/fdk-aac')

diff --git a/media-libs/fdk-aac/Manifest b/media-libs/fdk-aac/Manifest
index 1f997ee0f8e6..0c1e47ff4908 100644
--- a/media-libs/fdk-aac/Manifest
+++ b/media-libs/fdk-aac/Manifest
@@ -1,2 +1,3 @@
 DIST fdk-aac-0.1.3.tar.gz 1982695 BLAKE2B 5624f255356dc6b1f3f021aaef22eaaf1b1e25da1bcbc5e1d936d0835eb151f06c498fbe362e2c6afb04d018e69ccdb6e3ca4be4407378df3cf4229000ca0973 SHA512 1cc78bdb31f0896b71de85afbebeb5f8ed97affccf74c20ad2c36e6baead0199f83bf987a28872a1229b116c17c161e4bbe197c5108fd749fd508ebfeeb7df56
 DIST fdk-aac-0.1.5.tar.gz 2091081 BLAKE2B 16dd8606f87480fbf13d06b9628ff8c4fef418b5c55fbf99931d25ee9de6c1dd710760be8766af995d0d678e8c94b2d3b17aa6cd0f5b2512ae9d4478d985d72a SHA512 579e96dae5638cfe2d3d5e84ab24a72ed50ed3b5a9d3c6eb2f434d3a5f4c575877a2ecf6cd7cf7a528eb2811b2014a861eaaac9ea5fc617c6423587525766f00
+DIST fdk-aac-0.1.6.tar.gz 2091618 BLAKE2B e3036879e21677ea0ba6d6a030aff0568572e420217479b19312bc64daf0a4e94c1a0a6de561baa79f362186777f1414a4a1eb89bf80c1268767564f1a82708b SHA512 d4d14debeb6e424f4e2a1458ed7bebaa2c45ce54170c6e679286fd965f52286b6a6c1e944edbb4ea2302c3bb789c0f3cdab9c0d89618014ba4250b2f04d71d12
diff --git a/media-libs/fdk-aac/fdk-aac-0.1.6.ebuild b/media-libs/fdk-aac/fdk-aac-0.1.6.ebuild
new file mode 100644
index 000000000000..228a1c8a1bf6
--- /dev/null
+++ b/media-libs/fdk-aac/fdk-aac-0.1.6.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mstorsjo/${PN}.git"
+	[[ ${PV%9999} != "" ]] && EGIT_BRANCH="release/${PV%.9999}"
+	inherit autotools git-r3
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
+	if [[ ${PV%_p*} != ${PV} ]]; then # Gentoo snapshot
+		SRC_URI="mirror://gentoo/${P}.tar.xz"
+	else # Official release
+		SRC_URI="mirror://sourceforge/opencore-amr/${P}.tar.gz"
+	fi
+fi
+
+inherit multilib-minimal
+
+DESCRIPTION="Fraunhofer AAC codec library"
+HOMEPAGE="https://sourceforge.net/projects/opencore-amr/"
+LICENSE="FraunhoferFDK"
+# subslot == N where N is libfdk-aac.so.N
+SLOT="0/1"
+
+IUSE="static-libs examples"
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable examples example)
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use examples; then
+		mv "${ED%/}/usr/bin/"{,fdk-}aac-enc || die
+	fi
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	use examples && einfo "aac-enc was renamed to fdk-aac-enc to prevent file collision with other packages"
+}
-- 
cgit v1.2.3-65-gdbad