From 05d1238ef466bbb8f266f6ed6cd749b0db1b242a Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Thu, 11 Nov 2021 14:14:07 +0100
Subject: media-libs/grilo: Bump to 0.3.14

Bug: https://bugs.gentoo.org/809713
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
---
 media-libs/grilo/Manifest            |  1 +
 media-libs/grilo/grilo-0.3.14.ebuild | 77 ++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)
 create mode 100644 media-libs/grilo/grilo-0.3.14.ebuild

(limited to 'media-libs/grilo')

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 217be1dd1ccf..ef250142196e 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1 +1,2 @@
 DIST grilo-0.3.13.tar.xz 236420 BLAKE2B 8f891507edce92bccbc12aa9ecce78e8bd0804e548deec9a3651a656a27e9e87156e8cd7e1959a662c23e16fe958ff09f95755f825116f785784271883579dfc SHA512 b229b9b7524c1be63ed8891a9438844ebb87013074b394330f25316feb015040b304cd98bf3c89dc3248e6898c587a5e51666776a5b4ba5026a80ee8ad3e6d01
+DIST grilo-0.3.14.tar.xz 236620 BLAKE2B 25c81fb9b4ebce456f24aea19518d0a9c3b98a216e50fe9cbe9fa8b7e089535b5d695fb915497e8f812a0fc964b1f2b591fb0c0e382771af88318d94dd659fe8 SHA512 128464e51040ea121b19640c708fa996743a18e047ab11d4c3047db7d24732eac6da65393c16f987e834cb301385ef0c349eb0fabd7d67b2d10a230c8f03492a
diff --git a/media-libs/grilo/grilo-0.3.14.ebuild b/media-libs/grilo/grilo-0.3.14.ebuild
new file mode 100644
index 000000000000..d8c385b4b579
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.14.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson python-any-r1 vala xdg
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk gtk-doc +introspection +playlist test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# oauth could be optional if meson is patched - used for flickr oauth in grilo-test-ui tool
+RDEPEND="
+	>=dev-libs/glib-2.58:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.41.3:2.4[introspection?]
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+
+	gtk? (
+		net-libs/liboauth
+		>=x11-libs/gtk+-3.14:3
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.3
+	)
+	${PYTHON_DEPS}
+	test? ( sys-apps/dbus )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:'grilo':'grilo-${SLOT%/*}':" doc/grilo/meson.build || die
+
+	# Drop explicit unversioned vapigen check
+	sed -i -e "/find_program.*vapigen/d" meson.build || die
+
+	# Don't build examples; they get embedded in gtk-doc, thus we don't install the sources with USE=examples either
+	sed -i -e "/subdir('examples')/d" meson.build || die
+
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable-grl-net=true # Fails to build
+		$(meson_use playlist enable-grl-pls)
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk enable-test-ui)
+		$(meson_use vala enable-vala)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
-- 
cgit v1.2.3-65-gdbad