From abf46f6453217ef149c1e0f0d11f322fde68964e Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sun, 29 Jul 2018 00:05:12 +0300
Subject: media-libs/grilo: bump to 0.3.6

Package-Manager: Portage-2.3.43, Repoman-2.3.10
---
 media-libs/grilo/Manifest           |  1 +
 media-libs/grilo/grilo-0.3.6.ebuild | 88 +++++++++++++++++++++++++++++++++++++
 2 files changed, 89 insertions(+)
 create mode 100644 media-libs/grilo/grilo-0.3.6.ebuild

(limited to 'media-libs/grilo')

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index d7a2c11cd4a3..18351aaf41d1 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1,2 +1,3 @@
 DIST grilo-0.2.15.tar.xz 627196 BLAKE2B 3277f2588413e364835954f971c986451837b6992858d48273280d511a4d1ef4a8075924aaa3d4426818952e9f4d65c1b2dff7d3e255b2cbf30a8f73f740f91a SHA512 ac0a76d9075e5383fe1a56277b23986a8ec8e86f01f3f782ac7dc79539904712c22295c679243604b619f24088a1210622e0699b5601678264bd7651012ded3e
 DIST grilo-0.3.4.tar.xz 644616 BLAKE2B 4e8a7ba7da065b91cf780e4ec5da96b7a63534c2ef22d80cea21853a9373bca59359d2384e6f549689221a4eb1da495037c88e9adaea6c786005963c97a9aa1e SHA512 d3800a1873364dc8b56748924eee71928f9e08ad82d8ee2ffaf265cca7e26476081e543f42f26db57c088b2b063f86244e6718116710fc39fdea623868992145
+DIST grilo-0.3.6.tar.xz 653864 BLAKE2B 58570975b2c4623b2a43b441c60d88146080327a86018bfd1a37967d35b6389e5102915296ceba1a8ebf23d27a3e4f8d23eeb59555a6c5cd0ca596b5ab674878 SHA512 175cf61a43aea8456a41f4dce7694fac50e854cf6340ed0671f233e6188fa34347c1e7308aac99bc49d081c36747776b9a8c1c5cc7c0be00a1df2c9d015d8849
diff --git a/media-libs/grilo/grilo-0.3.6.ebuild b/media-libs/grilo/grilo-0.3.6.ebuild
new file mode 100644
index 000000000000..f94923394370
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.6.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+VALA_MIN_API_VERSION="0.28"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk examples +introspection +network playlist test vala"
+REQUIRED_USE="test? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/libxml2:2
+	net-libs/liboauth
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9:= )
+	network? ( >=net-libs/libsoup-2.41.3:2.4 )
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.10
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	test? (
+		${PYTHON_DEPS}
+		media-plugins/grilo-plugins:${SLOT%/*} )
+"
+# eautoreconf requires gnome-common
+
+pkg_setup() {
+	# Python tests are currently commented out, but this is done via in exit(0) in testrunner.py
+	# thus it still needs $PYTHON set up, which python-any-r1_pkg_setup will do for us
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -e "s:GETTEXT_PACKAGE=grilo$:GETTEXT_PACKAGE=grilo-${SLOT%/*}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+
+	# Don't build examples
+	sed -e '/SUBDIRS/s/examples//' \
+		-i Makefile.am -i Makefile.in || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# --enable-debug only changes CFLAGS, useless for us
+	gnome2_src_configure \
+		--disable-static \
+		--disable-debug \
+		$(use_enable gtk test-ui) \
+		$(use_enable introspection) \
+		$(use_enable network grl-net) \
+		$(use_enable playlist grl-pls) \
+		$(use_enable test tests) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+	# Upstream made this conditional on gtk-doc build...
+	DOC_MODULE_VERSION=${SLOT%/*} \
+	emake -C doc install DESTDIR="${ED}"
+
+	if use examples; then
+		# Install example code
+		insinto /usr/share/doc/${PF}/examples
+		doins "${S}"/examples/*.c
+	fi
+}
-- 
cgit v1.2.3-18-g5258