From 5dd01db3ceaa1f24a5178ad38eaf8e20cdbab4f5 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Fri, 6 Oct 2017 09:34:36 +0200
Subject: media-libs/jbig2dec: Bump to version 0.14

Package-Manager: Portage-2.3.11, Repoman-2.3.3
---
 media-libs/jbig2dec/jbig2dec-0.14.ebuild | 44 ++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 media-libs/jbig2dec/jbig2dec-0.14.ebuild

(limited to 'media-libs/jbig2dec/jbig2dec-0.14.ebuild')

diff --git a/media-libs/jbig2dec/jbig2dec-0.14.ebuild b/media-libs/jbig2dec/jbig2dec-0.14.ebuild
new file mode 100644
index 000000000000..ce8602ec84b5
--- /dev/null
+++ b/media-libs/jbig2dec/jbig2dec-0.14.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="A decoder implementation of the JBIG2 image compression format"
+HOMEPAGE="http://ghostscript.com/jbig2dec.html"
+SRC_URI="http://downloads.ghostscript.com/public/${PN}/${P}.tar.gz
+	test? ( http://jbig2dec.sourceforge.net/ubc/jb2streams.zip )"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x86-solaris"
+IUSE="png static-libs test"
+
+RDEPEND="png? ( media-libs/libpng:0= )"
+DEPEND="${RDEPEND}
+	test? ( app-arch/unzip )"
+
+RESTRICT="test"
+# bug 324275
+
+DOCS=( CHANGES README )
+
+src_prepare() {
+	default
+
+	if use test; then
+		mkdir "${WORKDIR}/ubc" || die
+		mv -v "${WORKDIR}"/*.jb2 "${WORKDIR}/ubc/" || die
+		mv -v "${WORKDIR}"/*.bmp "${WORKDIR}/ubc/" || die
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with png libpng)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm {} + || die
+}
-- 
cgit v1.2.3