From 3c8aa035785724e5c7dad46b35c25500d4c7135a Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 19 Jul 2020 18:28:15 +0000
Subject: media-libs/jbig2dec: security bump to 0.18

Bump to 0.18, but while we're here,
add support for newer Pythons at build time.

We include two additional upstream patches
post-release which look security-relevant.

Bug: https://bugs.gentoo.org/719730
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-libs/jbig2dec/jbig2dec-0.18.ebuild | 73 ++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 media-libs/jbig2dec/jbig2dec-0.18.ebuild

(limited to 'media-libs/jbig2dec/jbig2dec-0.18.ebuild')

diff --git a/media-libs/jbig2dec/jbig2dec-0.18.ebuild b/media-libs/jbig2dec/jbig2dec-0.18.ebuild
new file mode 100644
index 000000000000..7586ed8797c8
--- /dev/null
+++ b/media-libs/jbig2dec/jbig2dec-0.18.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="A decoder implementation of the JBIG2 image compression format"
+HOMEPAGE="https://jbig2dec.com/"
+SRC_URI="https://github.com/ArtifexSoftware/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+	test? ( http://jbig2dec.sourceforge.net/ubc/jb2streams.zip )"
+
+LICENSE="AGPL-3"
+SLOT="0/$(ver_cut 1-2)" #698428
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="png static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		app-arch/unzip
+		${PYTHON_DEPS}
+	)
+"
+
+RDEPEND="png? ( media-libs/libpng:0= )"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES README )
+
+PATCHES=(
+	"${FILESDIR}/${P}-extra-overflow-checks.patch"
+	"${FILESDIR}/${P}-overflow-IAID.patch"
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	if use test; then
+		mkdir "${WORKDIR}/ubc" || die
+		mv -v "${WORKDIR}"/*.jb2 "${WORKDIR}/ubc/" || die
+		mv -v "${WORKDIR}"/*.bmp "${WORKDIR}/ubc/" || die
+	fi
+
+	# We only need configure.ac and config_types.h.in
+	sed -i \
+		-e '/^# do we need automake?/,/^autoheader/d' \
+		-e '/echo "  $AUTOM.*/,$d' \
+		autogen.sh \
+		|| die "failed to modify autogen.sh"
+
+	./autogen.sh || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with png libpng)
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -exec rm {} + || die
+}
-- 
cgit v1.2.3-65-gdbad