From 5634882295653c659a27748253c4ab44ab8a4ba7 Mon Sep 17 00:00:00 2001
From: Thomas Beierlein <tomjbe@gentoo.org>
Date: Wed, 21 Dec 2016 07:27:25 +0100
Subject: media-radio/xlog: Version bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1
---
 media-radio/xlog/xlog-2.0.14.ebuild | 68 +++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 media-radio/xlog/xlog-2.0.14.ebuild

(limited to 'media-radio/xlog/xlog-2.0.14.ebuild')

diff --git a/media-radio/xlog/xlog-2.0.14.ebuild b/media-radio/xlog/xlog-2.0.14.ebuild
new file mode 100644
index 000000000000..42a6c4c3c7c1
--- /dev/null
+++ b/media-radio/xlog/xlog-2.0.14.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools fdo-mime toolchain-funcs
+MY_P=${P/_}
+
+DESCRIPTION="An amateur radio logging program"
+HOMEPAGE="http://www.nongnu.org/xlog"
+SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="media-libs/hamlib
+	dev-libs/glib:2
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS data/doc/THANKS NEWS README )
+
+src_prepare() {
+	eapply -p0 "${FILESDIR}/${PN}-2.0.7-desktop.patch"
+
+	# Let portage handle updating mime/desktop databases,
+	eapply -p0 "${FILESDIR}/${PN}-2.0.13-desktop-update.patch"
+	# Drop -Werror
+	sed -i -e "s:-Werror::" configure.ac || die
+	# fix underlinking
+	sed -i -e "s:HAMLIB_LIBS@:HAMLIB_LIBS@ -lm:g" src/Makefile.am || die
+	eautoreconf
+
+	eapply_user
+}
+
+src_configure() {
+	# mime-update causes file collisions if enabled
+	econf --disable-mime-update --disable-desktop-update \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	docompress -x /usr/share/doc/${PF}/{KEYS,ChangeLog,TODO,BUGS}
+	einstalldocs
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
-- 
cgit v1.2.3-18-g5258