From cf4d82c159f7ca1c2bd49fbb4ba92ea2d9449cb2 Mon Sep 17 00:00:00 2001
From: Gergely Nagy <ngg@ngg.hu>
Date: Sun, 27 Nov 2016 22:35:28 +0100
Subject: media-sound/musescore: Version bump and dependency fixes.

* Bumped version to 2.0.3
* Added missing dependency to dev-qt/designer
* Removed audiofile dependency (it can only build its own variant)
* media-libs/libsndfile is always needed
* Added alsa USE flag
* Fixed CMAKE args for using portaudio and pulseaudio
* Rebased patch on the new version
Closes: https://github.com/gentoo/gentoo/pull/2937
---
 media-sound/musescore/musescore-2.0.3.ebuild | 62 ++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 media-sound/musescore/musescore-2.0.3.ebuild

(limited to 'media-sound/musescore/musescore-2.0.3.ebuild')

diff --git a/media-sound/musescore/musescore-2.0.3.ebuild b/media-sound/musescore/musescore-2.0.3.ebuild
new file mode 100644
index 000000000000..ab54ba659dcf
--- /dev/null
+++ b/media-sound/musescore/musescore-2.0.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="WYSIWYG Music Score Typesetter"
+HOMEPAGE="http://musescore.org/"
+SRC_URI="https://github.com/musescore/MuseScore/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug jack mp3 portaudio pulseaudio"
+
+RDEPEND="
+	dev-qt/designer:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qthelp:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtxmlpatterns:5
+	>=media-libs/freetype-2.5.2
+	media-libs/libsndfile
+	sys-libs/zlib
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	mp3? ( media-sound/lame )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	"
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.3-fix-buildsystem.patch"
+)
+S="${WORKDIR}/MuseScore-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_ALSA="$(usex alsa)"
+		-DBUILD_JACK="$(usex jack)"
+		-DBUILD_LAME="$(usex mp3)"
+		-DBUILD_PORTAUDIO="$(usex portaudio)"
+		-DBUILD_PULSEAUDIO="$(usex pulseaudio)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cd "${BUILD_DIR}" || die
+	cmake-utils_src_make -j1 lrelease manpages
+	cmake-utils_src_compile
+}
-- 
cgit v1.2.3-65-gdbad