From e9f237d795f95b10fd8295b5180fcdb97a1cb28c Mon Sep 17 00:00:00 2001
From: Jimi Huotari <chiitoo@gentoo.org>
Date: Fri, 3 May 2019 20:00:04 +0300
Subject: media-video/obs-studio: drop 23.1.0 (r0)

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-video/obs-studio/obs-studio-23.1.0.ebuild | 129 ------------------------
 1 file changed, 129 deletions(-)
 delete mode 100644 media-video/obs-studio/obs-studio-23.1.0.ebuild

(limited to 'media-video')

diff --git a/media-video/obs-studio/obs-studio-23.1.0.ebuild b/media-video/obs-studio/obs-studio-23.1.0.ebuild
deleted file mode 100644
index 6ee58e5d0a11..000000000000
--- a/media-video/obs-studio/obs-studio-23.1.0.ebuild
+++ /dev/null
@@ -1,129 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python{3_5,3_6,3_7} )
-
-inherit cmake-utils python-single-r1 xdg-utils
-
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
-	EGIT_SUBMODULES=()
-else
-	SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-fi
-
-DESCRIPTION="Software for Recording and Streaming Live Video Content"
-HOMEPAGE="https://obsproject.com"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="+alsa fdk imagemagick jack luajit nvenc pulseaudio python speex truetype v4l"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-BDEPEND="
-	luajit? ( dev-lang/swig )
-	python? ( dev-lang/swig )
-"
-DEPEND="
-	>=dev-libs/jansson-2.5
-	dev-qt/qtcore:5
-	dev-qt/qtdeclarative:5
-	dev-qt/qtgui:5
-	dev-qt/qtmultimedia:5
-	dev-qt/qtnetwork:5
-	dev-qt/qtquickcontrols:5
-	dev-qt/qtsql:5
-	dev-qt/qttest:5
-	dev-qt/qtwidgets:5
-	dev-qt/qtx11extras:5
-	media-video/ffmpeg:=[x264]
-	net-misc/curl
-	x11-libs/libXcomposite
-	x11-libs/libXinerama
-	x11-libs/libXrandr
-	alsa? ( media-libs/alsa-lib )
-	fdk? ( media-libs/fdk-aac:= )
-	imagemagick? ( media-gfx/imagemagick:= )
-	jack? ( virtual/jack )
-	luajit? ( dev-lang/luajit:2 )
-	nvenc? (
-		|| (
-			<media-video/ffmpeg-4[nvenc]
-			>=media-video/ffmpeg-4[video_cards_nvidia]
-		)
-	)
-	pulseaudio? ( media-sound/pulseaudio )
-	python? ( ${PYTHON_DEPS} )
-	speex? ( media-libs/speexdsp )
-	truetype? (
-		media-libs/fontconfig
-		media-libs/freetype
-	)
-	v4l? ( media-libs/libv4l )
-"
-RDEPEND="${DEPEND}"
-
-CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_configure() {
-	local libdir=$(get_libdir)
-	local mycmakeargs=(
-		-DDISABLE_ALSA=$(usex !alsa)
-		-DDISABLE_FREETYPE=$(usex !truetype)
-		-DDISABLE_JACK=$(usex !jack)
-		-DDISABLE_LIBFDK=$(usex !fdk)
-		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
-		-DDISABLE_SPEEXDSP=$(usex !speex)
-		-DDISABLE_V4L2=$(usex !v4l)
-		-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
-		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
-		-DOBS_VERSION_OVERRIDE=${PV}
-		-DUNIX_STRUCTURE=1
-	)
-
-	if use luajit || use python; then
-		mycmakeargs+=(
-			-DDISABLE_LUA=$(usex !luajit)
-			-DDISABLE_PYTHON=$(usex !python)
-			-DENABLE_SCRIPTING=yes
-		)
-	else
-		mycmakeargs+=( -DENABLE_SCRIPTING=no )
-	fi
-
-	cmake-utils_src_configure
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-
-	if ! use alsa && ! use pulseaudio; then
-		elog
-		elog "For the audio capture features to be available,"
-		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
-		elog "be enabled."
-		elog
-	fi
-
-	if ! has_version "sys-apps/dbus"; then
-		elog
-		elog "The 'sys-apps/dbus' package is not installed, but"
-		elog "could be used for disabling hibernating, screensaving,"
-		elog "and sleeping.  Where it is not installed,"
-		elog "'xdg-screensaver reset' is used instead"
-		elog "(if 'x11-misc/xdg-utils' is installed)."
-		elog
-	fi
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}
-- 
cgit v1.2.3-65-gdbad