From cd7bdd8a269e0a22dad2a80991a1f4752867fc9b Mon Sep 17 00:00:00 2001
From: Sergey Popov <pinkbyte@gentoo.org>
Date: Wed, 9 Oct 2019 16:13:35 +0300
Subject: net-dialup/accel-ppp: version bump, update live ebuild

Signed-off-by: Sergey Popov <pinkbyte@gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11
---
 net-dialup/accel-ppp/Manifest                |   1 +
 net-dialup/accel-ppp/accel-ppp-1.12.0.ebuild | 107 +++++++++++++++++++++++++++
 net-dialup/accel-ppp/accel-ppp-9999.ebuild   |   8 +-
 3 files changed, 112 insertions(+), 4 deletions(-)
 create mode 100644 net-dialup/accel-ppp/accel-ppp-1.12.0.ebuild

(limited to 'net-dialup/accel-ppp')

diff --git a/net-dialup/accel-ppp/Manifest b/net-dialup/accel-ppp/Manifest
index 8cd346959bb8..e8ecf5cc9a3b 100644
--- a/net-dialup/accel-ppp/Manifest
+++ b/net-dialup/accel-ppp/Manifest
@@ -1 +1,2 @@
 DIST accel-ppp-1.11.1_p20180320.tar.bz2 1634359 BLAKE2B 97ca709ef3740c2ac1d75f6fba3acbf9229c3cb48f3a55735eaa14b74c2b0af96d637cbb145bc9e98a5b245704806cdc3d8f9d8692809626e0f73d73702c4a0a SHA512 a8a2420332c02087e45bbaab25831ae5d2d370fd56b29db77c267083badc22b90ca4b0ec7335e13250ac8f150002b2a3c343cfba6c2378932778777dc936d914
+DIST accel-ppp-1.12.0.tar 6758400 BLAKE2B 776c0946decec2d88a0dfeb8e840573ae8d53d53d0fe921604667eaf4a5658e7d0cfa57f0b54eb61fcdf62b7a62a94ee405a01ad2a66ab76042d59cc3f79d42b SHA512 f1d3b31ca36395a429214b7599a43755317d89391c5631dfd02df79ed8dd51c39f75fc56ac625fbc6e7d5b0f9c85699c5da612eb4e8af9eae8ad2d9b13a187ba
diff --git a/net-dialup/accel-ppp/accel-ppp-1.12.0.ebuild b/net-dialup/accel-ppp/accel-ppp-1.12.0.ebuild
new file mode 100644
index 000000000000..f2e7d2b54cce
--- /dev/null
+++ b/net-dialup/accel-ppp/accel-ppp-1.12.0.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils flag-o-matic linux-info linux-mod
+
+DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
+HOMEPAGE="https://sourceforge.net/projects/accel-ppp/"
+SRC_URI="https://download.sourceforge.net/accel-ppp/${P}.tar.bz2 -> ${P}.tar"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc ipoe lua postgres radius shaper snmp valgrind"
+
+RDEPEND="lua? ( dev-lang/lua:0 )
+	postgres? ( dev-db/postgresql:* )
+	snmp? ( net-analyzer/net-snmp )
+	dev-libs/libpcre
+	dev-libs/openssl:0="
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+PDEPEND="net-dialup/ppp-scripts"
+
+DOCS=( README )
+
+CONFIG_CHECK="~L2TP ~PPPOE ~PPTP"
+
+REQUIRED_USE="valgrind? ( debug )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.11.1-socklen.patch"
+)
+
+pkg_setup() {
+	if use ipoe; then
+		linux-mod_pkg_setup
+		set_arch_to_kernel
+	else
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	sed -i  -e "/mkdir/d" \
+		-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'
+
+	# Do not install kernel modules like that - breaks sandbox!
+	sed -i -e '/modules_install/d' \
+		drivers/ipoe/CMakeLists.txt \
+		drivers/vlan_mon/CMakeLists.txt || die
+
+	# Fix version
+	sed -i -e "s/1.11/${PV}/" drivers/ipoe/ipoe.c || die
+	sed -i -e "s/1.11/${PV}/" drivers/vlan_mon/vlan_mon.c || die
+
+	# Bug #549918
+	append-ldflags -Wl,-z,lazy
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local libdir="$(get_libdir)"
+	# There must be also dev-libs/tomcrypt (TOMCRYPT) as crypto alternative to OpenSSL
+	local mycmakeargs=(
+		-DLIB_SUFFIX="${libdir#lib}"
+		-DBUILD_IPOE_DRIVER="$(usex ipoe)"
+		-DBUILD_PPTP_DRIVER=no
+		-DBUILD_VLAN_MON_DRIVER="$(usex ipoe)"
+		-DCRYPTO=OPENSSL
+		-DLOG_PGSQL="$(usex postgres)"
+		-DLUA="$(usex lua)"
+		-DMEMDEBUG="$(usex debug)"
+		-DNETSNMP="$(usex snmp)"
+		-DRADIUS="$(usex radius)"
+		-DSHAPER="$(usex shaper)"
+		$(use debug && echo "-DVALGRIND=$(usex valgrind)")
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	if use ipoe; then
+		local MODULE_NAMES="ipoe(accel-ppp:${BUILD_DIR}/drivers/ipoe/driver) vlan_mon(accel-ppp:${BUILD_DIR}/drivers/vlan_mon/driver)"
+		linux-mod_src_install
+	fi
+
+	cmake-utils_src_install
+
+	use doc && dodoc -r rfc
+
+	if use snmp; then
+		insinto /usr/share/snmp/mibs
+		doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
+	fi
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}d
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}d
+
+	dodir /var/log/accel-ppp
+}
diff --git a/net-dialup/accel-ppp/accel-ppp-9999.ebuild b/net-dialup/accel-ppp/accel-ppp-9999.ebuild
index ff874dac8811..a05fd2d9a09d 100644
--- a/net-dialup/accel-ppp/accel-ppp-9999.ebuild
+++ b/net-dialup/accel-ppp/accel-ppp-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2019 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-EGIT_REPO_URI="git://git.code.sf.net/p/accel-ppp/code"
+EGIT_REPO_URI="https://git.code.sf.net/p/accel-ppp/code"
 inherit cmake-utils flag-o-matic git-r3 linux-info linux-mod
 
 DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
@@ -19,7 +19,7 @@ RDEPEND="lua? ( dev-lang/lua:0 )
 	postgres? ( dev-db/postgresql:* )
 	snmp? ( net-analyzer/net-snmp )
 	dev-libs/libpcre
-	dev-libs/openssl:0"
+	dev-libs/openssl:0="
 DEPEND="${RDEPEND}
 	valgrind? ( dev-util/valgrind )"
 PDEPEND="net-dialup/ppp-scripts"
-- 
cgit v1.2.3-65-gdbad