From f5be0fa19f11299cbecedced0eb1524342b8ab7f Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Mon, 2 Jan 2017 01:18:10 +0100
Subject: net-dns/libidn2: Version bump.

Package-Manager: Portage-2.3.3, Repoman-2.3.1
---
 net-dns/libidn2/libidn2-0.13.ebuild | 55 +++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 net-dns/libidn2/libidn2-0.13.ebuild

(limited to 'net-dns/libidn2/libidn2-0.13.ebuild')

diff --git a/net-dns/libidn2/libidn2-0.13.ebuild b/net-dns/libidn2/libidn2-0.13.ebuild
new file mode 100644
index 000000000000..c5848cefce7c
--- /dev/null
+++ b/net-dns/libidn2/libidn2-0.13.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="An implementation of the IDNA2008 specifications (RFCs 5890, 5891, 5892, 5893)"
+HOMEPAGE="https://www.gnu.org/software/libidn/#libidn2"
+SRC_URI="
+	mirror://gnu-alpha/libidn/${P}.tar.gz
+"
+
+LICENSE="GPL-2+ LGPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~ppc-aix ~x64-freebsd ~x86-freebsd ~hppa-hpux ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="
+	dev-libs/libunistring[${MULTILIB_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	dev-lang/perl
+	sys-apps/help2man
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.12-Werror.patch
+	"${FILESDIR}"/${PN}-0.12-examples.patch
+	"${FILESDIR}"/${PN}-0.12-gengetopt.patch
+	"${FILESDIR}"/${PN}-0.12-noinstall.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	# tr46map.c is already present
+	touch gentr46map -r tr46map.c
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	default
+
+	prune_libtool_files
+}
-- 
cgit v1.2.3-65-gdbad