From 52ee7fd636e3cf8105ddddd4440d113c8fb0ed3e Mon Sep 17 00:00:00 2001
From: Jimi Huotari <chiitoo@gentoo.org>
Date: Wed, 19 Jan 2022 03:19:35 +0200
Subject: net-im/qtox: add version 1.17.4

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/23867
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 net-im/qtox/Manifest           |  1 +
 net-im/qtox/qtox-1.17.4.ebuild | 91 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 net-im/qtox/qtox-1.17.4.ebuild

(limited to 'net-im')

diff --git a/net-im/qtox/Manifest b/net-im/qtox/Manifest
index e044567d91c0..0a3bcc3dca01 100644
--- a/net-im/qtox/Manifest
+++ b/net-im/qtox/Manifest
@@ -1,2 +1,3 @@
 DIST qTox-1.16.3.tar.gz 4256757 BLAKE2B 70103e2d912da86dab63424586c642a73614b4a408a53634b146d1e401d5b328a2b8c81c472a94e0e8804d774f693c1250e7263b263e80abef5e111372f29232 SHA512 a857266ffcf32b1963e3a4428501299ce19f3c087087583115dc01e41934fc31d52ea54d781fa93ec7e21f6e3303b4e22383ecaaa7f1f1dbf32d740db73aca4c
 DIST qTox-1.17.3.tar.gz 4765213 BLAKE2B 3bffa351da01b436edc9c80c481845f6c6399c930ac1601e1676b7dec22ccfbf37c082c3a30ab71e2295c96bb427b36a718f960ffc75e700d5c29605f7bf0ac0 SHA512 e7534e40aed06aaeba57a201b7315ae2bd361f80971969b95b00fea0a6cbe106c2ea337485c47b350c07a9e3b74947c8b2feb206899292c29621e057b630ca56
+DIST qTox-1.17.4.tar.gz 4778657 BLAKE2B 5edcb6b6f997eeb4a332c23477d4c5021085cf8c62be596b0eb4771963f450bc96de6c2dc30ec3cfc98577f20bf618e8fc2478fc34af8a8810fc538a5ccc787b SHA512 00dd2b4492e6dbf90b038bd1e5263ba96c969fb5d879b5680401ad090ffe6aaa70ff487f2e88f93c573f2e1a7e6ca50a75dfe7b51fc56fc4d08cac076bfd75d0
diff --git a/net-im/qtox/qtox-1.17.4.ebuild b/net-im/qtox/qtox-1.17.4.ebuild
new file mode 100644
index 000000000000..825ce6aa14d1
--- /dev/null
+++ b/net-im/qtox/qtox-1.17.4.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/qTox/qTox.git"
+else
+	MY_P="qTox-${PV}"
+	SRC_URI="https://github.com/qTox/qTox/releases/download/v${PV}/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/qTox"
+fi
+
+DESCRIPTION="Instant messaging client using the encrypted p2p Tox protocol"
+HOMEPAGE="https://qtox.github.io/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="notification +spellcheck test X"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-db/sqlcipher
+	dev-libs/libsodium:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[gif,jpeg,png,X(-)]
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-gfx/qrencode:=
+	media-libs/libexif
+	media-libs/openal
+	media-video/ffmpeg:=[webp,v4l]
+	>=net-libs/tox-0.2.13:=[av]
+	notification? ( x11-libs/snorenotify )
+	spellcheck? ( kde-frameworks/sonnet:5 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+	X? ( x11-base/xorg-proto )
+"
+
+DOCS=( CHANGELOG.md README.md doc/user_manual_en.md )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# bug 628574
+	if ! use test; then
+		sed -i CMakeLists.txt -e "/include(Testing)/d" || die
+		sed -i cmake/Dependencies.cmake -e "/find_package(Qt5Test/d" || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPLATFORM_EXTENSIONS=$(usex X)
+		-DUPDATE_CHECK=OFF
+		-DUSE_CCACHE=OFF
+		-DSPELL_CHECK=$(usex spellcheck)
+		-DSVGZ_ICON=ON
+		-DASAN=OFF
+		-DDESKTOP_NOTIFICATIONS=$(usex notification)
+		-DSTRICT_OPTIONS=OFF
+	)
+
+	[[ ${PV} != 9999 ]] && mycmakeargs+=( -DGIT_DESCRIBE=${PV} )
+
+	cmake_src_configure
+}
+
+src_test() {
+	# The excluded tests require network access.
+	cmake_src_test -E "test_(bsu|core)"
+}
-- 
cgit v1.2.3-65-gdbad