From 1a2fe95298c222bb7f9338cc16eee1e3f797ee0e Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sat, 4 Apr 2020 16:39:54 +0300
Subject: net-libs/gnome-online-accounts: bump to 3.34.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 net-libs/gnome-online-accounts/Manifest            |  1 +
 .../gnome-online-accounts-3.34.1.ebuild            | 82 ++++++++++++++++++++++
 net-libs/gnome-online-accounts/metadata.xml        |  2 -
 3 files changed, 83 insertions(+), 2 deletions(-)
 create mode 100644 net-libs/gnome-online-accounts/gnome-online-accounts-3.34.1.ebuild

(limited to 'net-libs')

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 7e8ec70c747e..e57d9fe18b90 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1 +1,2 @@
 DIST gnome-online-accounts-3.32.1.tar.xz 863252 BLAKE2B 69345a5e7a9ccfef231cb012a1e3240a31db898f32b654f6275fd18e027eebe5cda07b4a0f8fea1447ca33ac120d8476aea7d2c824238b327c0c207009fcae7c SHA512 548e6c983899bc1f4093fcf0b7b08819f2803182f52c2cdfb4cffa8bfb00e513322973fdfce2aeadeb52b0cd43c7c1e3941cff187927577cefb4fba51f4fda5b
+DIST gnome-online-accounts-3.34.1.tar.xz 856288 BLAKE2B 99a6c242dd57acf009a2b4451287fff5bbc61b0aeb0396b13368b179d1b1604b413ff9dcb56bf4415c990cb4f2cb434a0fcf17b9381dcb5055a99985249af5d4 SHA512 233f1b15d4a7bdbee4ed85ba252ea0d9af2ac15a2edd3ce2b40d76434285fd093f07375313a599fa191f8df1551eb37f48c4784e389fcbaec0565bb3aba28426
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.34.1.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.34.1.ebuild
new file mode 100644
index 000000000000..f2f39420fa86
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.34.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.52:2
+	>=app-crypt/libsecret-0.5
+	>=dev-libs/json-glib-0.16
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/rest:0.7
+	>=net-libs/webkit-gtk-2.12.0:4
+	>=x11-libs/gtk+-3.19.12:3
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	kerberos? (
+		app-crypt/gcr:0=[gtk]
+		app-crypt/mit-krb5 )
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gtk-doc-am-1.3
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	gnome2_src_configure \
+		--disable-static \
+		--enable-backend \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-flickr \
+		--enable-foursquare \
+		--enable-imap-smtp \
+		--enable-lastfm \
+		--enable-media-server \
+		--enable-owncloud \
+		--enable-pocket \
+		--enable-windows-live \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable kerberos) \
+		$(use_enable kerberos fedora) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
diff --git a/net-libs/gnome-online-accounts/metadata.xml b/net-libs/gnome-online-accounts/metadata.xml
index 009604473b86..77001fb72285 100644
--- a/net-libs/gnome-online-accounts/metadata.xml
+++ b/net-libs/gnome-online-accounts/metadata.xml
@@ -8,7 +8,5 @@
 <use>
 	<flag name="gnome">Use <pkg>gnome-base/gnome-control-center</pkg>
 		to set GNOME online accounts preferences</flag>
-	<!-- <flag name="telepathy">Provide widget to configure the telepathy
-		frawework</flag> -->
 </use>
 </pkgmetadata>
-- 
cgit v1.2.3-65-gdbad