From 1e474561c433802204379d91553f024b8f4be590 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Wed, 17 Apr 2019 14:20:02 +0200
Subject: net-libs/libpsl: Bump to version 0.21.0

Package-Manager: Portage-2.3.63, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 net-libs/libpsl/Manifest             |  1 +
 net-libs/libpsl/libpsl-0.21.0.ebuild | 74 ++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 net-libs/libpsl/libpsl-0.21.0.ebuild

(limited to 'net-libs')

diff --git a/net-libs/libpsl/Manifest b/net-libs/libpsl/Manifest
index e9fbf64bcb00..dc145ccabd7f 100644
--- a/net-libs/libpsl/Manifest
+++ b/net-libs/libpsl/Manifest
@@ -1 +1,2 @@
 DIST libpsl-0.20.2.tar.gz 9228099 BLAKE2B d53b8a036ba557704c4d3a498b35fd25e3dfc466d5161040d02b7d8d47af2138cce2bdbb8203fca0591408440f1b4cfab776fe0d2ecd68959f426d903cab08d4 SHA512 fa9f6f7f0447d9fe00f5dfca5262c56ff26217eea44d0f7fc1e5d982224c41874e753f0aa06dd9e5d7d03d4f04e3dacd4f36034cc8dd0fc6e2c28b49a23e62fe
+DIST libpsl-0.21.0.tar.gz 9217951 BLAKE2B fd93b71ae4969bb920af26e10e0e419dab62db37197046b0f4e4a0e009a150582df6d4c8fe33218fa8be869e6ad9688d3c325c3f635da5560e29269daa461668 SHA512 165c4f0b0640a813d512bd916e1532e32e43c8c81a5efd048f3a5b07b1b3c9129b4c4b5008b8b11a7c1b3914caea17564321389cd350bf1d687d53a97f2afa4d
diff --git a/net-libs/libpsl/libpsl-0.21.0.ebuild b/net-libs/libpsl/libpsl-0.21.0.ebuild
new file mode 100644
index 000000000000..fd6aa857e238
--- /dev/null
+++ b/net-libs/libpsl/libpsl-0.21.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python{2_7,3_{5,6,7}})
+
+inherit multilib-minimal python-any-r1
+
+DESCRIPTION="C library for the Public Suffix List"
+HOMEPAGE="https://github.com/rockdaboot/libpsl"
+SRC_URI="https://github.com/rockdaboot/${PN}/releases/download/${P}/${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm64 ~hppa ~ia64 ~s390 ~sparc ~x86"
+IUSE="icu +idn +man"
+
+RDEPEND="
+	icu? ( !idn? ( dev-libs/icu:=[${MULTILIB_USEDEP}] ) )
+	idn? (
+		dev-libs/libunistring[${MULTILIB_USEDEP}]
+		net-dns/libidn2:=[${MULTILIB_USEDEP}]
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+	man? ( dev-libs/libxslt )
+"
+
+pkg_pretend() {
+	if use icu && use idn ; then
+		ewarn "\"icu\" and \"idn\" USE flags are enabled."
+		ewarn "Using \"idn\"."
+	fi
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-asan
+		--disable-cfi
+		--disable-ubsan
+		$(use_enable man)
+	)
+
+	# Prefer idn even if icu is in USE as well
+	if use idn ; then
+		myeconfargs+=(
+			--enable-builtin=libidn2
+			--enable-runtime=libidn2
+		)
+	elif use icu ; then
+		myeconfargs+=(
+			--enable-builtin=libicu
+			--enable-runtime=libicu
+		)
+	else
+		myeconfargs+=( --disable-runtime )
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	default
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}
-- 
cgit v1.2.3